[svn] / trunk / xvidcore / src / dct / x86_asm / idct_mmx.asm Repository:
ViewVC logotype

Annotation of /trunk/xvidcore/src/dct/x86_asm/idct_mmx.asm

Parent Directory Parent Directory | Revision Log Revision Log

Revision 1877 - (view) (download)

1 : edgomez 1382 ;/****************************************************************************
2 :     ; *
3 :     ; * XVID MPEG-4 VIDEO CODEC
4 :     ; * - MMX and XMM forward discrete cosine transform -
5 :     ; *
6 :     ; * Copyright(C) 2001 Peter Ross <pross@xvid.org>
7 :     ; *
8 :     ; * This program is free software; you can redistribute it and/or modify it
9 :     ; * under the terms of the GNU General Public License as published by
10 :     ; * the Free Software Foundation; either version 2 of the License, or
11 :     ; * (at your option) any later version.
12 :     ; *
13 :     ; * This program is distributed in the hope that it will be useful,
14 :     ; * but WITHOUT ANY WARRANTY; without even the implied warranty of
15 :     ; * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
16 :     ; * GNU General Public License for more details.
17 :     ; *
18 :     ; * You should have received a copy of the GNU General Public License
19 :     ; * along with this program; if not, write to the Free Software
20 :     ; * Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307 USA
21 :     ; *
22 : Isibaar 1877 ; * $Id: idct_mmx.asm,v 1.15 2009-09-16 17:07:58 Isibaar Exp $
23 : edgomez 1382 ; *
24 :     ; ***************************************************************************/
25 :    
26 :     ; ****************************************************************************
27 :     ;
28 : edgomez 851 ; Originally provided by Intel at AP-922
29 :     ; http://developer.intel.com/vtune/cbts/strmsimd/922down.htm
30 :     ; (See more app notes at http://developer.intel.com/vtune/cbts/strmsimd/appnotes.htm)
31 :     ; but in a limited edition.
32 :     ; New macro implements a column part for precise iDCT
33 : edgomez 1382 ; The routine precision now satisfies IEEE standard 1180-1990.
34 : edgomez 851 ;
35 : edgomez 1382 ; Copyright(C) 2000-2001 Peter Gubanov <peter@elecard.net.ru>
36 :     ; Rounding trick Copyright(C) 2000 Michel Lespinasse <walken@zoy.org>
37 : edgomez 851 ;
38 :     ; http://www.elecard.com/peter/idct.html
39 :     ; http://www.linuxvideo.org/mpeg2dec/
40 :     ;
41 : edgomez 1382 ; ***************************************************************************/
42 : Isibaar 3 ;
43 :     ; These examples contain code fragments for first stage iDCT 8x8
44 :     ; (for rows) and first stage DCT 8x8 (for columns)
45 :     ;
46 :    
47 : edgomez 1382 ;=============================================================================
48 :     ; Macros and other preprocessor constants
49 :     ;=============================================================================
50 :    
51 : Isibaar 1795 %include "nasm.inc"
52 : Isibaar 3
53 : edgomez 1382 %define BITS_INV_ACC 5 ; 4 or 5 for IEEE
54 : Isibaar 3 %define SHIFT_INV_ROW 16 - BITS_INV_ACC
55 :     %define SHIFT_INV_COL 1 + BITS_INV_ACC
56 :     %define RND_INV_ROW 1024 * (6 - BITS_INV_ACC) ; 1 << (SHIFT_INV_ROW-1)
57 :     %define RND_INV_COL 16 * (BITS_INV_ACC - 3) ; 1 << (SHIFT_INV_COL-1)
58 : edgomez 1382 %define RND_INV_CORR RND_INV_COL - 1 ; correction -1.0 and round
59 : Isibaar 3
60 : edgomez 1382 %define BITS_FRW_ACC 3 ; 2 or 3 for accuracy
61 : Isibaar 3 %define SHIFT_FRW_COL BITS_FRW_ACC
62 :     %define SHIFT_FRW_ROW BITS_FRW_ACC + 17
63 : edgomez 1382 %define RND_FRW_ROW 262144*(BITS_FRW_ACC - 1) ; 1 << (SHIFT_FRW_ROW-1)
64 : Isibaar 3
65 : edgomez 1382 ;=============================================================================
66 :     ; Local Data (Read Only)
67 :     ;=============================================================================
68 :    
69 : Isibaar 1795 DATA
70 : Isibaar 3
71 : edgomez 1382 ;-----------------------------------------------------------------------------
72 :     ; Various memory constants (trigonometric values or rounding values)
73 :     ;-----------------------------------------------------------------------------
74 : Isibaar 3
75 : Isibaar 1795 ALIGN SECTION_ALIGN
76 : edgomez 1382 one_corr:
77 :     dw 1, 1, 1, 1
78 :     round_inv_row:
79 :     dd RND_INV_ROW, RND_INV_ROW
80 :     round_inv_col:
81 :     dw RND_INV_COL, RND_INV_COL, RND_INV_COL, RND_INV_COL
82 :     round_inv_corr:
83 :     dw RND_INV_CORR, RND_INV_CORR, RND_INV_CORR, RND_INV_CORR
84 :     round_frw_row:
85 :     dd RND_FRW_ROW, RND_FRW_ROW
86 :     tg_1_16:
87 :     dw 13036, 13036, 13036, 13036 ; tg * (2<<16) + 0.5
88 :     tg_2_16:
89 :     dw 27146, 27146, 27146, 27146 ; tg * (2<<16) + 0.5
90 :     tg_3_16:
91 :     dw -21746, -21746, -21746, -21746 ; tg * (2<<16) + 0.5
92 :     cos_4_16:
93 :     dw -19195, -19195, -19195, -19195 ; cos * (2<<16) + 0.5
94 :     ocos_4_16:
95 :     dw 23170, 23170, 23170, 23170 ; cos * (2<<15) + 0.5
96 :     otg_3_16:
97 :     dw 21895, 21895, 21895, 21895 ; tg * (2<<16) + 0.5
98 : Isibaar 3
99 :     %if SHIFT_INV_ROW == 12 ; assume SHIFT_INV_ROW == 12
100 : edgomez 1382 rounder_0:
101 :     dd 65536, 65536
102 :     rounder_4:
103 :     dd 0, 0
104 :     rounder_1:
105 :     dd 7195, 7195
106 :     rounder_7
107 :     dd 1024, 1024
108 :     rounder_2:
109 :     dd 4520, 4520
110 :     rounder_6:
111 :     dd 1024, 1024
112 :     rounder_3:
113 :     dd 2407, 2407
114 :     rounder_5:
115 :     dd 240, 240
116 : Isibaar 3
117 :     %elif SHIFT_INV_ROW == 11 ; assume SHIFT_INV_ROW == 11
118 : edgomez 1382 rounder_0:
119 :     dd 65536, 65536
120 :     rounder_4:
121 :     dd 0, 0
122 :     rounder_1:
123 :     dd 3597, 3597
124 :     rounder_7:
125 :     dd 512, 512
126 :     rounder_2:
127 :     dd 2260, 2260
128 :     rounder_6:
129 :     dd 512, 512
130 :     rounder_3:
131 :     dd 1203, 1203
132 :     rounder_5:
133 :     dd 120, 120
134 : Isibaar 3 %else
135 :    
136 : edgomez 1382 %error invalid SHIFT_INV_ROW
137 : Isibaar 3
138 :     %endif
139 :    
140 : edgomez 1382 ;-----------------------------------------------------------------------------
141 : Isibaar 3 ;
142 :     ; The first stage iDCT 8x8 - inverse DCTs of rows
143 :     ;
144 :     ;-----------------------------------------------------------------------------
145 :     ; The 8-point inverse DCT direct algorithm
146 :     ;-----------------------------------------------------------------------------
147 :     ;
148 :     ; static const short w[32] = {
149 :     ; FIX(cos_4_16), FIX(cos_2_16), FIX(cos_4_16), FIX(cos_6_16),
150 :     ; FIX(cos_4_16), FIX(cos_6_16), -FIX(cos_4_16), -FIX(cos_2_16),
151 :     ; FIX(cos_4_16), -FIX(cos_6_16), -FIX(cos_4_16), FIX(cos_2_16),
152 :     ; FIX(cos_4_16), -FIX(cos_2_16), FIX(cos_4_16), -FIX(cos_6_16),
153 :     ; FIX(cos_1_16), FIX(cos_3_16), FIX(cos_5_16), FIX(cos_7_16),
154 :     ; FIX(cos_3_16), -FIX(cos_7_16), -FIX(cos_1_16), -FIX(cos_5_16),
155 :     ; FIX(cos_5_16), -FIX(cos_1_16), FIX(cos_7_16), FIX(cos_3_16),
156 :     ; FIX(cos_7_16), -FIX(cos_5_16), FIX(cos_3_16), -FIX(cos_1_16) };
157 :     ;
158 :     ; #define DCT_8_INV_ROW(x, y)
159 :     ; {
160 :     ; int a0, a1, a2, a3, b0, b1, b2, b3;
161 :     ;
162 :     ; a0 =x[0]*w[0]+x[2]*w[1]+x[4]*w[2]+x[6]*w[3];
163 :     ; a1 =x[0]*w[4]+x[2]*w[5]+x[4]*w[6]+x[6]*w[7];
164 :     ; a2 = x[0] * w[ 8] + x[2] * w[ 9] + x[4] * w[10] + x[6] * w[11];
165 :     ; a3 = x[0] * w[12] + x[2] * w[13] + x[4] * w[14] + x[6] * w[15];
166 :     ; b0 = x[1] * w[16] + x[3] * w[17] + x[5] * w[18] + x[7] * w[19];
167 :     ; b1 = x[1] * w[20] + x[3] * w[21] + x[5] * w[22] + x[7] * w[23];
168 :     ; b2 = x[1] * w[24] + x[3] * w[25] + x[5] * w[26] + x[7] * w[27];
169 :     ; b3 = x[1] * w[28] + x[3] * w[29] + x[5] * w[30] + x[7] * w[31];
170 :     ;
171 :     ; y[0] = SHIFT_ROUND ( a0 + b0 );
172 :     ; y[1] = SHIFT_ROUND ( a1 + b1 );
173 :     ; y[2] = SHIFT_ROUND ( a2 + b2 );
174 :     ; y[3] = SHIFT_ROUND ( a3 + b3 );
175 :     ; y[4] = SHIFT_ROUND ( a3 - b3 );
176 :     ; y[5] = SHIFT_ROUND ( a2 - b2 );
177 :     ; y[6] = SHIFT_ROUND ( a1 - b1 );
178 :     ; y[7] = SHIFT_ROUND ( a0 - b0 );
179 :     ; }
180 :     ;
181 :     ;-----------------------------------------------------------------------------
182 :     ;
183 :     ; In this implementation the outputs of the iDCT-1D are multiplied
184 :     ; for rows 0,4 - by cos_4_16,
185 :     ; for rows 1,7 - by cos_1_16,
186 :     ; for rows 2,6 - by cos_2_16,
187 :     ; for rows 3,5 - by cos_3_16
188 :     ; and are shifted to the left for better accuracy
189 :     ;
190 :     ; For the constants used,
191 :     ; FIX(float_const) = (short) (float_const * (1<<15) + 0.5)
192 :     ;
193 : edgomez 1382 ;-----------------------------------------------------------------------------
194 : Isibaar 3
195 : edgomez 1382 ;-----------------------------------------------------------------------------
196 :     ; Tables for mmx processors
197 :     ;-----------------------------------------------------------------------------
198 : Isibaar 3
199 :     ; Table for rows 0,4 - constants are multiplied by cos_4_16
200 : edgomez 1382 tab_i_04_mmx:
201 :     dw 16384, 16384, 16384, -16384 ; movq-> w06 w04 w02 w00
202 :     dw 21407, 8867, 8867, -21407 ; w07 w05 w03 w01
203 :     dw 16384, -16384, 16384, 16384 ; w14 w12 w10 w08
204 :     dw -8867, 21407, -21407, -8867 ; w15 w13 w11 w09
205 :     dw 22725, 12873, 19266, -22725 ; w22 w20 w18 w16
206 :     dw 19266, 4520, -4520, -12873 ; w23 w21 w19 w17
207 :     dw 12873, 4520, 4520, 19266 ; w30 w28 w26 w24
208 :     dw -22725, 19266, -12873, -22725 ; w31 w29 w27 w25
209 : Isibaar 3
210 :     ; Table for rows 1,7 - constants are multiplied by cos_1_16
211 : edgomez 1382 tab_i_17_mmx:
212 :     dw 22725, 22725, 22725, -22725 ; movq-> w06 w04 w02 w00
213 :     dw 29692, 12299, 12299, -29692 ; w07 w05 w03 w01
214 :     dw 22725, -22725, 22725, 22725 ; w14 w12 w10 w08
215 :     dw -12299, 29692, -29692, -12299 ; w15 w13 w11 w09
216 :     dw 31521, 17855, 26722, -31521 ; w22 w20 w18 w16
217 :     dw 26722, 6270, -6270, -17855 ; w23 w21 w19 w17
218 :     dw 17855, 6270, 6270, 26722 ; w30 w28 w26 w24
219 :     dw -31521, 26722, -17855, -31521 ; w31 w29 w27 w25
220 : Isibaar 3
221 :     ; Table for rows 2,6 - constants are multiplied by cos_2_16
222 : edgomez 1382 tab_i_26_mmx:
223 :     dw 21407, 21407, 21407, -21407 ; movq-> w06 w04 w02 w00
224 :     dw 27969, 11585, 11585, -27969 ; w07 w05 w03 w01
225 :     dw 21407, -21407, 21407, 21407 ; w14 w12 w10 w08
226 :     dw -11585, 27969, -27969, -11585 ; w15 w13 w11 w09
227 :     dw 29692, 16819, 25172, -29692 ; w22 w20 w18 w16
228 :     dw 25172, 5906, -5906, -16819 ; w23 w21 w19 w17
229 :     dw 16819, 5906, 5906, 25172 ; w30 w28 w26 w24
230 :     dw -29692, 25172, -16819, -29692 ; w31 w29 w27 w25
231 : Isibaar 3
232 :     ; Table for rows 3,5 - constants are multiplied by cos_3_16
233 : edgomez 1382 tab_i_35_mmx:
234 :     dw 19266, 19266, 19266, -19266 ; movq-> w06 w04 w02 w00
235 :     dw 25172, 10426, 10426, -25172 ; w07 w05 w03 w01
236 :     dw 19266, -19266, 19266, 19266 ; w14 w12 w10 w08
237 :     dw -10426, 25172, -25172, -10426 ; w15 w13 w11 w09
238 :     dw 26722, 15137, 22654, -26722 ; w22 w20 w18 w16
239 :     dw 22654, 5315, -5315, -15137 ; w23 w21 w19 w17
240 :     dw 15137, 5315, 5315, 22654 ; w30 w28 w26 w24
241 :     dw -26722, 22654, -15137, -26722 ; w31 w29 w27 w25
242 : Isibaar 3
243 :     ;-----------------------------------------------------------------------------
244 : edgomez 1382 ; Tables for xmm processors
245 :     ;-----------------------------------------------------------------------------
246 : Isibaar 3
247 :     ; %3 for rows 0,4 - constants are multiplied by cos_4_16
248 : edgomez 1382 tab_i_04_xmm:
249 :     dw 16384, 21407, 16384, 8867 ; movq-> w05 w04 w01 w00
250 :     dw 16384, 8867, -16384, -21407 ; w07 w06 w03 w02
251 :     dw 16384, -8867, 16384, -21407 ; w13 w12 w09 w08
252 :     dw -16384, 21407, 16384, -8867 ; w15 w14 w11 w10
253 :     dw 22725, 19266, 19266, -4520 ; w21 w20 w17 w16
254 :     dw 12873, 4520, -22725, -12873 ; w23 w22 w19 w18
255 :     dw 12873, -22725, 4520, -12873 ; w29 w28 w25 w24
256 :     dw 4520, 19266, 19266, -22725 ; w31 w30 w27 w26
257 : Isibaar 3
258 :     ; %3 for rows 1,7 - constants are multiplied by cos_1_16
259 : edgomez 1382 tab_i_17_xmm:
260 :     dw 22725, 29692, 22725, 12299 ; movq-> w05 w04 w01 w00
261 :     dw 22725, 12299, -22725, -29692 ; w07 w06 w03 w02
262 :     dw 22725, -12299, 22725, -29692 ; w13 w12 w09 w08
263 :     dw -22725, 29692, 22725, -12299 ; w15 w14 w11 w10
264 :     dw 31521, 26722, 26722, -6270 ; w21 w20 w17 w16
265 :     dw 17855, 6270, -31521, -17855 ; w23 w22 w19 w18
266 :     dw 17855, -31521, 6270, -17855 ; w29 w28 w25 w24
267 :     dw 6270, 26722, 26722, -31521 ; w31 w30 w27 w26
268 : Isibaar 3
269 :     ; %3 for rows 2,6 - constants are multiplied by cos_2_16
270 : edgomez 1382 tab_i_26_xmm:
271 :     dw 21407, 27969, 21407, 11585 ; movq-> w05 w04 w01 w00
272 :     dw 21407, 11585, -21407, -27969 ; w07 w06 w03 w02
273 :     dw 21407, -11585, 21407, -27969 ; w13 w12 w09 w08
274 :     dw -21407, 27969, 21407, -11585 ; w15 w14 w11 w10
275 :     dw 29692, 25172, 25172, -5906 ; w21 w20 w17 w16
276 :     dw 16819, 5906, -29692, -16819 ; w23 w22 w19 w18
277 :     dw 16819, -29692, 5906, -16819 ; w29 w28 w25 w24
278 :     dw 5906, 25172, 25172, -29692 ; w31 w30 w27 w26
279 : Isibaar 3
280 :     ; %3 for rows 3,5 - constants are multiplied by cos_3_16
281 : edgomez 1382 tab_i_35_xmm:
282 :     dw 19266, 25172, 19266, 10426 ; movq-> w05 w04 w01 w00
283 :     dw 19266, 10426, -19266, -25172 ; w07 w06 w03 w02
284 :     dw 19266, -10426, 19266, -25172 ; w13 w12 w09 w08
285 :     dw -19266, 25172, 19266, -10426 ; w15 w14 w11 w10
286 :     dw 26722, 22654, 22654, -5315 ; w21 w20 w17 w16
287 :     dw 15137, 5315, -26722, -15137 ; w23 w22 w19 w18
288 :     dw 15137, -26722, 5315, -15137 ; w29 w28 w25 w24
289 :     dw 5315, 22654, 22654, -26722 ; w31 w30 w27 w26
290 : Isibaar 3
291 : edgomez 1382 ;=============================================================================
292 :     ; Helper macros for the code
293 :     ;=============================================================================
294 : Isibaar 3
295 :     ;-----------------------------------------------------------------------------
296 : edgomez 1382 ; DCT_8_INV_ROW_MMX INP, OUT, TABLE, ROUNDER
297 :     ;-----------------------------------------------------------------------------
298 : Isibaar 3
299 : edgomez 1382 %macro DCT_8_INV_ROW_MMX 4
300 :     movq mm0, [%1] ; 0 ; x3 x2 x1 x0
301 :     movq mm1, [%1+8] ; 1 ; x7 x6 x5 x4
302 :     movq mm2, mm0 ; 2 ; x3 x2 x1 x0
303 :     movq mm3, [%3] ; 3 ; w06 w04 w02 w00
304 :     punpcklwd mm0, mm1 ; x5 x1 x4 x0
305 :     movq mm5, mm0 ; 5 ; x5 x1 x4 x0
306 :     punpckldq mm0, mm0 ; x4 x0 x4 x0
307 :     movq mm4, [%3+8] ; 4 ; w07 w05 w03 w01
308 :     punpckhwd mm2, mm1 ; 1 ; x7 x3 x6 x2
309 :     pmaddwd mm3, mm0 ; x4*w06+x0*w04 x4*w02+x0*w00
310 :     movq mm6, mm2 ; 6 ; x7 x3 x6 x2
311 :     movq mm1, [%3+32] ; 1 ; w22 w20 w18 w16
312 :     punpckldq mm2, mm2 ; x6 x2 x6 x2
313 :     pmaddwd mm4, mm2 ; x6*w07+x2*w05 x6*w03+x2*w01
314 :     punpckhdq mm5, mm5 ; x5 x1 x5 x1
315 :     pmaddwd mm0, [%3+16] ; x4*w14+x0*w12 x4*w10+x0*w08
316 :     punpckhdq mm6, mm6 ; x7 x3 x7 x3
317 :     movq mm7, [%3+40] ; 7 ; w23 w21 w19 w17
318 :     pmaddwd mm1, mm5 ; x5*w22+x1*w20 x5*w18+x1*w16
319 :     paddd mm3, [%4] ; +%4
320 :     pmaddwd mm7, mm6 ; x7*w23+x3*w21 x7*w19+x3*w17
321 :     pmaddwd mm2, [%3+24] ; x6*w15+x2*w13 x6*w11+x2*w09
322 :     paddd mm3, mm4 ; 4 ; a1=sum(even1) a0=sum(even0)
323 :     pmaddwd mm5, [%3+48] ; x5*w30+x1*w28 x5*w26+x1*w24
324 :     movq mm4, mm3 ; 4 ; a1 a0
325 :     pmaddwd mm6, [%3+56] ; x7*w31+x3*w29 x7*w27+x3*w25
326 :     paddd mm1, mm7 ; 7 ; b1=sum(odd1) b0=sum(odd0)
327 :     paddd mm0, [%4] ; +%4
328 :     psubd mm3, mm1 ; a1-b1 a0-b0
329 :     psrad mm3, SHIFT_INV_ROW ; y6=a1-b1 y7=a0-b0
330 :     paddd mm1, mm4 ; 4 ; a1+b1 a0+b0
331 :     paddd mm0, mm2 ; 2 ; a3=sum(even3) a2=sum(even2)
332 :     psrad mm1, SHIFT_INV_ROW ; y1=a1+b1 y0=a0+b0
333 :     paddd mm5, mm6 ; 6 ; b3=sum(odd3) b2=sum(odd2)
334 :     movq mm4, mm0 ; 4 ; a3 a2
335 :     paddd mm0, mm5 ; a3+b3 a2+b2
336 :     psubd mm4, mm5 ; 5 ; a3-b3 a2-b2
337 :     psrad mm0, SHIFT_INV_ROW ; y3=a3+b3 y2=a2+b2
338 :     psrad mm4, SHIFT_INV_ROW ; y4=a3-b3 y5=a2-b2
339 :     packssdw mm1, mm0 ; 0 ; y3 y2 y1 y0
340 :     packssdw mm4, mm3 ; 3 ; y6 y7 y4 y5
341 :     movq mm7, mm4 ; 7 ; y6 y7 y4 y5
342 :     psrld mm4, 16 ; 0 y6 0 y4
343 :     pslld mm7, 16 ; y7 0 y5 0
344 :     movq [%2], mm1 ; 1 ; save y3 y2 y1 y0
345 :     por mm7, mm4 ; 4 ; y7 y6 y5 y4
346 :     movq [%2+8], mm7 ; 7 ; save y7 y6 y5 y4
347 :     %endmacro
348 : Isibaar 3
349 : edgomez 1382 ;-----------------------------------------------------------------------------
350 :     ; DCT_8_INV_ROW_XMM INP, OUT, TABLE, ROUNDER
351 :     ;-----------------------------------------------------------------------------
352 : Isibaar 3
353 : edgomez 1382 %macro DCT_8_INV_ROW_XMM 4
354 :     movq mm0, [%1] ; 0 ; x3 x2 x1 x0
355 :     movq mm1, [%1+8] ; 1 ; x7 x6 x5 x4
356 :     movq mm2, mm0 ; 2 ; x3 x2 x1 x0
357 :     movq mm3, [%3] ; 3 ; w05 w04 w01 w00
358 :     pshufw mm0, mm0, 10001000b ; x2 x0 x2 x0
359 :     movq mm4, [%3+8] ; 4 ; w07 w06 w03 w02
360 :     movq mm5, mm1 ; 5 ; x7 x6 x5 x4
361 :     pmaddwd mm3, mm0 ; x2*w05+x0*w04 x2*w01+x0*w00
362 :     movq mm6, [%3+32] ; 6 ; w21 w20 w17 w16
363 :     pshufw mm1, mm1, 10001000b ; x6 x4 x6 x4
364 :     pmaddwd mm4, mm1 ; x6*w07+x4*w06 x6*w03+x4*w02
365 :     movq mm7, [%3+40] ; 7 ; w23 w22 w19 w18
366 :     pshufw mm2, mm2, 11011101b ; x3 x1 x3 x1
367 :     pmaddwd mm6, mm2 ; x3*w21+x1*w20 x3*w17+x1*w16
368 :     pshufw mm5, mm5, 11011101b ; x7 x5 x7 x5
369 :     pmaddwd mm7, mm5 ; x7*w23+x5*w22 x7*w19+x5*w18
370 :     paddd mm3, [%4] ; +%4
371 :     pmaddwd mm0, [%3+16] ; x2*w13+x0*w12 x2*w09+x0*w08
372 :     paddd mm3, mm4 ; 4 ; a1=sum(even1) a0=sum(even0)
373 :     pmaddwd mm1, [%3+24] ; x6*w15+x4*w14 x6*w11+x4*w10
374 :     movq mm4, mm3 ; 4 ; a1 a0
375 :     pmaddwd mm2, [%3+48] ; x3*w29+x1*w28 x3*w25+x1*w24
376 :     paddd mm6, mm7 ; 7 ; b1=sum(odd1) b0=sum(odd0)
377 :     pmaddwd mm5, [%3+56] ; x7*w31+x5*w30 x7*w27+x5*w26
378 :     paddd mm3, mm6 ; a1+b1 a0+b0
379 :     paddd mm0, [%4] ; +%4
380 :     psrad mm3, SHIFT_INV_ROW ; y1=a1+b1 y0=a0+b0
381 :     paddd mm0, mm1 ; 1 ; a3=sum(even3) a2=sum(even2)
382 :     psubd mm4, mm6 ; 6 ; a1-b1 a0-b0
383 :     movq mm7, mm0 ; 7 ; a3 a2
384 :     paddd mm2, mm5 ; 5 ; b3=sum(odd3) b2=sum(odd2)
385 :     paddd mm0, mm2 ; a3+b3 a2+b2
386 :     psrad mm4, SHIFT_INV_ROW ; y6=a1-b1 y7=a0-b0
387 :     psubd mm7, mm2 ; 2 ; a3-b3 a2-b2
388 :     psrad mm0, SHIFT_INV_ROW ; y3=a3+b3 y2=a2+b2
389 :     psrad mm7, SHIFT_INV_ROW ; y4=a3-b3 y5=a2-b2
390 :     packssdw mm3, mm0 ; 0 ; y3 y2 y1 y0
391 :     packssdw mm7, mm4 ; 4 ; y6 y7 y4 y5
392 :     movq [%2], mm3 ; 3 ; save y3 y2 y1 y0
393 :     pshufw mm7, mm7, 10110001b ; y7 y6 y5 y4
394 :     movq [%2+8], mm7 ; 7 ; save y7 y6 y5 y4
395 : Isibaar 3 %endmacro
396 :    
397 : edgomez 1382 ;-----------------------------------------------------------------------------
398 : Isibaar 3 ;
399 :     ; The first stage DCT 8x8 - forward DCTs of columns
400 :     ;
401 :     ; The %2puts are multiplied
402 :     ; for rows 0,4 - on cos_4_16,
403 :     ; for rows 1,7 - on cos_1_16,
404 :     ; for rows 2,6 - on cos_2_16,
405 :     ; for rows 3,5 - on cos_3_16
406 :     ; and are shifted to the left for rise of accuracy
407 :     ;
408 :     ;-----------------------------------------------------------------------------
409 :     ;
410 :     ; The 8-point scaled forward DCT algorithm (26a8m)
411 :     ;
412 :     ;-----------------------------------------------------------------------------
413 :     ;
414 :     ; #define DCT_8_FRW_COL(x, y)
415 :     ;{
416 :     ; short t0, t1, t2, t3, t4, t5, t6, t7;
417 :     ; short tp03, tm03, tp12, tm12, tp65, tm65;
418 :     ; short tp465, tm465, tp765, tm765;
419 :     ;
420 :     ; t0 = LEFT_SHIFT ( x[0] + x[7] );
421 :     ; t1 = LEFT_SHIFT ( x[1] + x[6] );
422 :     ; t2 = LEFT_SHIFT ( x[2] + x[5] );
423 :     ; t3 = LEFT_SHIFT ( x[3] + x[4] );
424 :     ; t4 = LEFT_SHIFT ( x[3] - x[4] );
425 :     ; t5 = LEFT_SHIFT ( x[2] - x[5] );
426 :     ; t6 = LEFT_SHIFT ( x[1] - x[6] );
427 :     ; t7 = LEFT_SHIFT ( x[0] - x[7] );
428 :     ;
429 :     ; tp03 = t0 + t3;
430 :     ; tm03 = t0 - t3;
431 :     ; tp12 = t1 + t2;
432 :     ; tm12 = t1 - t2;
433 :     ;
434 :     ; y[0] = tp03 + tp12;
435 :     ; y[4] = tp03 - tp12;
436 :     ;
437 :     ; y[2] = tm03 + tm12 * tg_2_16;
438 :     ; y[6] = tm03 * tg_2_16 - tm12;
439 :     ;
440 :     ; tp65 =(t6 +t5 )*cos_4_16;
441 :     ; tm65 =(t6 -t5 )*cos_4_16;
442 :     ;
443 :     ; tp765 = t7 + tp65;
444 :     ; tm765 = t7 - tp65;
445 :     ; tp465 = t4 + tm65;
446 :     ; tm465 = t4 - tm65;
447 :     ;
448 :     ; y[1] = tp765 + tp465 * tg_1_16;
449 :     ; y[7] = tp765 * tg_1_16 - tp465;
450 :     ; y[5] = tm765 * tg_3_16 + tm465;
451 :     ; y[3] = tm765 - tm465 * tg_3_16;
452 :     ;}
453 :     ;
454 : edgomez 1382 ;-----------------------------------------------------------------------------
455 : Isibaar 3
456 : edgomez 1382 ;-----------------------------------------------------------------------------
457 : Isibaar 3 ; DCT_8_INV_COL_4 INP,OUT
458 : edgomez 1382 ;-----------------------------------------------------------------------------
459 : Isibaar 3
460 : edgomez 1382 %macro DCT_8_INV_COL 2
461 :     movq mm0, [tg_3_16]
462 :     movq mm3, [%1+16*3]
463 :     movq mm1, mm0 ; tg_3_16
464 :     movq mm5, [%1+16*5]
465 :     pmulhw mm0, mm3 ; x3*(tg_3_16-1)
466 :     movq mm4, [tg_1_16]
467 :     pmulhw mm1, mm5 ; x5*(tg_3_16-1)
468 :     movq mm7, [%1+16*7]
469 :     movq mm2, mm4 ; tg_1_16
470 :     movq mm6, [%1+16*1]
471 :     pmulhw mm4, mm7 ; x7*tg_1_16
472 :     paddsw mm0, mm3 ; x3*tg_3_16
473 :     pmulhw mm2, mm6 ; x1*tg_1_16
474 :     paddsw mm1, mm3 ; x3+x5*(tg_3_16-1)
475 :     psubsw mm0, mm5 ; x3*tg_3_16-x5 = tm35
476 :     movq mm3, [ocos_4_16]
477 :     paddsw mm1, mm5 ; x3+x5*tg_3_16 = tp35
478 :     paddsw mm4, mm6 ; x1+tg_1_16*x7 = tp17
479 :     psubsw mm2, mm7 ; x1*tg_1_16-x7 = tm17
480 :     movq mm5, mm4 ; tp17
481 :     movq mm6, mm2 ; tm17
482 :     paddsw mm5, mm1 ; tp17+tp35 = b0
483 :     psubsw mm6, mm0 ; tm17-tm35 = b3
484 :     psubsw mm4, mm1 ; tp17-tp35 = t1
485 :     paddsw mm2, mm0 ; tm17+tm35 = t2
486 :     movq mm7, [tg_2_16]
487 :     movq mm1, mm4 ; t1
488 :     ; movq [SCRATCH+0], mm5 ; save b0
489 :     movq [%2+3*16], mm5 ; save b0
490 :     paddsw mm1, mm2 ; t1+t2
491 :     ; movq [SCRATCH+8], mm6 ; save b3
492 :     movq [%2+5*16], mm6 ; save b3
493 :     psubsw mm4, mm2 ; t1-t2
494 :     movq mm5, [%1+2*16]
495 :     movq mm0, mm7 ; tg_2_16
496 :     movq mm6, [%1+6*16]
497 :     pmulhw mm0, mm5 ; x2*tg_2_16
498 :     pmulhw mm7, mm6 ; x6*tg_2_16
499 : Isibaar 3 ; slot
500 : edgomez 1382 pmulhw mm1, mm3 ; ocos_4_16*(t1+t2) = b1/2
501 : Isibaar 3 ; slot
502 : edgomez 1382 movq mm2, [%1+0*16]
503 :     pmulhw mm4, mm3 ; ocos_4_16*(t1-t2) = b2/2
504 :     psubsw mm0, mm6 ; t2*tg_2_16-x6 = tm26
505 :     movq mm3, mm2 ; x0
506 :     movq mm6, [%1+4*16]
507 :     paddsw mm7, mm5 ; x2+x6*tg_2_16 = tp26
508 :     paddsw mm2, mm6 ; x0+x4 = tp04
509 :     psubsw mm3, mm6 ; x0-x4 = tm04
510 :     movq mm5, mm2 ; tp04
511 :     movq mm6, mm3 ; tm04
512 :     psubsw mm2, mm7 ; tp04-tp26 = a3
513 :     paddsw mm3, mm0 ; tm04+tm26 = a1
514 :     paddsw mm1, mm1 ; b1
515 :     paddsw mm4, mm4 ; b2
516 :     paddsw mm5, mm7 ; tp04+tp26 = a0
517 :     psubsw mm6, mm0 ; tm04-tm26 = a2
518 :     movq mm7, mm3 ; a1
519 :     movq mm0, mm6 ; a2
520 :     paddsw mm3, mm1 ; a1+b1
521 :     paddsw mm6, mm4 ; a2+b2
522 :     psraw mm3, SHIFT_INV_COL ; dst1
523 :     psubsw mm7, mm1 ; a1-b1
524 :     psraw mm6, SHIFT_INV_COL ; dst2
525 :     psubsw mm0, mm4 ; a2-b2
526 :     ; movq mm1, [SCRATCH+0] ; load b0
527 :     movq mm1, [%2+3*16] ; load b0
528 :     psraw mm7, SHIFT_INV_COL ; dst6
529 :     movq mm4, mm5 ; a0
530 :     psraw mm0, SHIFT_INV_COL ; dst5
531 :     movq [%2+1*16], mm3
532 :     paddsw mm5, mm1 ; a0+b0
533 :     movq [%2+2*16], mm6
534 :     psubsw mm4, mm1 ; a0-b0
535 :     ; movq mm3, [SCRATCH+8] ; load b3
536 :     movq mm3, [%2+5*16] ; load b3
537 :     psraw mm5, SHIFT_INV_COL ; dst0
538 :     movq mm6, mm2 ; a3
539 :     psraw mm4, SHIFT_INV_COL ; dst7
540 :     movq [%2+5*16], mm0
541 :     paddsw mm2, mm3 ; a3+b3
542 :     movq [%2+6*16], mm7
543 :     psubsw mm6, mm3 ; a3-b3
544 :     movq [%2+0*16], mm5
545 :     psraw mm2, SHIFT_INV_COL ; dst3
546 :     movq [%2+7*16], mm4
547 :     psraw mm6, SHIFT_INV_COL ; dst4
548 :     movq [%2+3*16], mm2
549 :     movq [%2+4*16], mm6
550 : Isibaar 3 %endmacro
551 :    
552 :     ;=============================================================================
553 : edgomez 1382 ; Code
554 : Isibaar 3 ;=============================================================================
555 :    
556 : Isibaar 1844 TEXT
557 : Isibaar 3
558 : edgomez 1382 cglobal idct_mmx
559 : Isibaar 3 cglobal idct_xmm
560 :    
561 : edgomez 1382 ;-----------------------------------------------------------------------------
562 :     ; void idct_mmx(uint16_t block[64]);
563 :     ;-----------------------------------------------------------------------------
564 : Isibaar 3
565 : Isibaar 1795 ALIGN SECTION_ALIGN
566 : edgomez 1382 idct_mmx:
567 : Isibaar 1795 mov TMP0, prm1
568 : Isibaar 3
569 : edgomez 1382 ;; Process each row
570 : Isibaar 1795 DCT_8_INV_ROW_MMX TMP0+0*16, TMP0+0*16, tab_i_04_mmx, rounder_0
571 :     DCT_8_INV_ROW_MMX TMP0+1*16, TMP0+1*16, tab_i_17_mmx, rounder_1
572 :     DCT_8_INV_ROW_MMX TMP0+2*16, TMP0+2*16, tab_i_26_mmx, rounder_2
573 :     DCT_8_INV_ROW_MMX TMP0+3*16, TMP0+3*16, tab_i_35_mmx, rounder_3
574 :     DCT_8_INV_ROW_MMX TMP0+4*16, TMP0+4*16, tab_i_04_mmx, rounder_4
575 :     DCT_8_INV_ROW_MMX TMP0+5*16, TMP0+5*16, tab_i_35_mmx, rounder_5
576 :     DCT_8_INV_ROW_MMX TMP0+6*16, TMP0+6*16, tab_i_26_mmx, rounder_6
577 :     DCT_8_INV_ROW_MMX TMP0+7*16, TMP0+7*16, tab_i_17_mmx, rounder_7
578 : Isibaar 154
579 : edgomez 1382 ;; Process the columns (4 at a time)
580 : Isibaar 1795 DCT_8_INV_COL TMP0+0, TMP0+0
581 :     DCT_8_INV_COL TMP0+8, TMP0+8
582 : Isibaar 154
583 : edgomez 1382 ret
584 : Isibaar 1793 ENDFUNC
585 : Isibaar 154
586 : edgomez 1382 ;-----------------------------------------------------------------------------
587 :     ; void idct_xmm(uint16_t block[64]);
588 :     ;-----------------------------------------------------------------------------
589 : Isibaar 154
590 : Isibaar 1795 ALIGN SECTION_ALIGN
591 : edgomez 1382 idct_xmm:
592 : Isibaar 1795 mov TMP0, prm1
593 : Isibaar 154
594 : edgomez 1382 ;; Process each row
595 : Isibaar 1795 DCT_8_INV_ROW_XMM TMP0+0*16, TMP0+0*16, tab_i_04_xmm, rounder_0
596 :     DCT_8_INV_ROW_XMM TMP0+1*16, TMP0+1*16, tab_i_17_xmm, rounder_1
597 :     DCT_8_INV_ROW_XMM TMP0+2*16, TMP0+2*16, tab_i_26_xmm, rounder_2
598 :     DCT_8_INV_ROW_XMM TMP0+3*16, TMP0+3*16, tab_i_35_xmm, rounder_3
599 :     DCT_8_INV_ROW_XMM TMP0+4*16, TMP0+4*16, tab_i_04_xmm, rounder_4
600 :     DCT_8_INV_ROW_XMM TMP0+5*16, TMP0+5*16, tab_i_35_xmm, rounder_5
601 :     DCT_8_INV_ROW_XMM TMP0+6*16, TMP0+6*16, tab_i_26_xmm, rounder_6
602 :     DCT_8_INV_ROW_XMM TMP0+7*16, TMP0+7*16, tab_i_17_xmm, rounder_7
603 : Isibaar 154
604 : edgomez 1382 ;; Process the columns (4 at a time)
605 : Isibaar 1795 DCT_8_INV_COL TMP0+0, TMP0+0
606 :     DCT_8_INV_COL TMP0+8, TMP0+8
607 : Isibaar 154
608 : edgomez 1382 ret
609 : Isibaar 1793 ENDFUNC
610 : edgomez 1540
611 : Isibaar 1877 NON_EXEC_STACK
No admin address has been configured
 ViewVC Help
Powered by ViewVC 1.0.4