[svn] / trunk / xvidcore / src / dct / x86_asm / idct_mmx.asm Repository:
ViewVC logotype

Annotation of /trunk/xvidcore/src/dct/x86_asm/idct_mmx.asm

Parent Directory Parent Directory | Revision Log Revision Log

Revision 1793 - (view) (download)

1 : edgomez 1382 ;/****************************************************************************
2 :     ; *
3 :     ; * XVID MPEG-4 VIDEO CODEC
4 :     ; * - MMX and XMM forward discrete cosine transform -
5 :     ; *
6 :     ; * Copyright(C) 2001 Peter Ross <pross@xvid.org>
7 :     ; *
8 :     ; * This program is free software; you can redistribute it and/or modify it
9 :     ; * under the terms of the GNU General Public License as published by
10 :     ; * the Free Software Foundation; either version 2 of the License, or
11 :     ; * (at your option) any later version.
12 :     ; *
13 :     ; * This program is distributed in the hope that it will be useful,
14 :     ; * but WITHOUT ANY WARRANTY; without even the implied warranty of
15 :     ; * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
16 :     ; * GNU General Public License for more details.
17 :     ; *
18 :     ; * You should have received a copy of the GNU General Public License
19 :     ; * along with this program; if not, write to the Free Software
20 :     ; * Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307 USA
21 :     ; *
22 : Isibaar 1793 ; * $Id: idct_mmx.asm,v 1.12 2008-11-11 20:46:24 Isibaar Exp $
23 : edgomez 1382 ; *
24 :     ; ***************************************************************************/
25 :    
26 :     ; ****************************************************************************
27 :     ;
28 : edgomez 851 ; Originally provided by Intel at AP-922
29 :     ; http://developer.intel.com/vtune/cbts/strmsimd/922down.htm
30 :     ; (See more app notes at http://developer.intel.com/vtune/cbts/strmsimd/appnotes.htm)
31 :     ; but in a limited edition.
32 :     ; New macro implements a column part for precise iDCT
33 : edgomez 1382 ; The routine precision now satisfies IEEE standard 1180-1990.
34 : edgomez 851 ;
35 : edgomez 1382 ; Copyright(C) 2000-2001 Peter Gubanov <peter@elecard.net.ru>
36 :     ; Rounding trick Copyright(C) 2000 Michel Lespinasse <walken@zoy.org>
37 : edgomez 851 ;
38 :     ; http://www.elecard.com/peter/idct.html
39 :     ; http://www.linuxvideo.org/mpeg2dec/
40 :     ;
41 : edgomez 1382 ; ***************************************************************************/
42 : Isibaar 3 ;
43 :     ; These examples contain code fragments for first stage iDCT 8x8
44 :     ; (for rows) and first stage DCT 8x8 (for columns)
45 :     ;
46 :    
47 : edgomez 1382 BITS 32
48 : Isibaar 3
49 : edgomez 1382 ;=============================================================================
50 :     ; Macros and other preprocessor constants
51 :     ;=============================================================================
52 :    
53 :     %macro cglobal 1
54 : Isibaar 3 %ifdef PREFIX
55 : edgomez 1535 %ifdef MARK_FUNCS
56 : edgomez 1540 global _%1:function %1.endfunc-%1
57 :     %define %1 _%1:function %1.endfunc-%1
58 : Isibaar 1793 %define ENDFUNC .endfunc
59 : edgomez 1535 %else
60 :     global _%1
61 :     %define %1 _%1
62 : Isibaar 1793 %define ENDFUNC
63 : edgomez 1535 %endif
64 : Isibaar 3 %else
65 : edgomez 1535 %ifdef MARK_FUNCS
66 : edgomez 1540 global %1:function %1.endfunc-%1
67 : Isibaar 1793 %define ENDFUNC .endfunc
68 : edgomez 1535 %else
69 :     global %1
70 : Isibaar 1793 %define ENDFUNC
71 : edgomez 1535 %endif
72 : Isibaar 3 %endif
73 :     %endmacro
74 :    
75 : edgomez 1382 %define BITS_INV_ACC 5 ; 4 or 5 for IEEE
76 : Isibaar 3 %define SHIFT_INV_ROW 16 - BITS_INV_ACC
77 :     %define SHIFT_INV_COL 1 + BITS_INV_ACC
78 :     %define RND_INV_ROW 1024 * (6 - BITS_INV_ACC) ; 1 << (SHIFT_INV_ROW-1)
79 :     %define RND_INV_COL 16 * (BITS_INV_ACC - 3) ; 1 << (SHIFT_INV_COL-1)
80 : edgomez 1382 %define RND_INV_CORR RND_INV_COL - 1 ; correction -1.0 and round
81 : Isibaar 3
82 : edgomez 1382 %define BITS_FRW_ACC 3 ; 2 or 3 for accuracy
83 : Isibaar 3 %define SHIFT_FRW_COL BITS_FRW_ACC
84 :     %define SHIFT_FRW_ROW BITS_FRW_ACC + 17
85 : edgomez 1382 %define RND_FRW_ROW 262144*(BITS_FRW_ACC - 1) ; 1 << (SHIFT_FRW_ROW-1)
86 : Isibaar 3
87 : edgomez 1382 ;=============================================================================
88 :     ; Local Data (Read Only)
89 :     ;=============================================================================
90 :    
91 : suxen_drol 207 %ifdef FORMAT_COFF
92 : edgomez 1519 SECTION .rodata
93 : suxen_drol 207 %else
94 : edgomez 1519 SECTION .rodata align=16
95 : suxen_drol 207 %endif
96 : Isibaar 3
97 : edgomez 1382 ;-----------------------------------------------------------------------------
98 :     ; Various memory constants (trigonometric values or rounding values)
99 :     ;-----------------------------------------------------------------------------
100 : Isibaar 3
101 : edgomez 1382 ALIGN 16
102 :     one_corr:
103 :     dw 1, 1, 1, 1
104 :     round_inv_row:
105 :     dd RND_INV_ROW, RND_INV_ROW
106 :     round_inv_col:
107 :     dw RND_INV_COL, RND_INV_COL, RND_INV_COL, RND_INV_COL
108 :     round_inv_corr:
109 :     dw RND_INV_CORR, RND_INV_CORR, RND_INV_CORR, RND_INV_CORR
110 :     round_frw_row:
111 :     dd RND_FRW_ROW, RND_FRW_ROW
112 :     tg_1_16:
113 :     dw 13036, 13036, 13036, 13036 ; tg * (2<<16) + 0.5
114 :     tg_2_16:
115 :     dw 27146, 27146, 27146, 27146 ; tg * (2<<16) + 0.5
116 :     tg_3_16:
117 :     dw -21746, -21746, -21746, -21746 ; tg * (2<<16) + 0.5
118 :     cos_4_16:
119 :     dw -19195, -19195, -19195, -19195 ; cos * (2<<16) + 0.5
120 :     ocos_4_16:
121 :     dw 23170, 23170, 23170, 23170 ; cos * (2<<15) + 0.5
122 :     otg_3_16:
123 :     dw 21895, 21895, 21895, 21895 ; tg * (2<<16) + 0.5
124 : Isibaar 3
125 :     %if SHIFT_INV_ROW == 12 ; assume SHIFT_INV_ROW == 12
126 : edgomez 1382 rounder_0:
127 :     dd 65536, 65536
128 :     rounder_4:
129 :     dd 0, 0
130 :     rounder_1:
131 :     dd 7195, 7195
132 :     rounder_7
133 :     dd 1024, 1024
134 :     rounder_2:
135 :     dd 4520, 4520
136 :     rounder_6:
137 :     dd 1024, 1024
138 :     rounder_3:
139 :     dd 2407, 2407
140 :     rounder_5:
141 :     dd 240, 240
142 : Isibaar 3
143 :     %elif SHIFT_INV_ROW == 11 ; assume SHIFT_INV_ROW == 11
144 : edgomez 1382 rounder_0:
145 :     dd 65536, 65536
146 :     rounder_4:
147 :     dd 0, 0
148 :     rounder_1:
149 :     dd 3597, 3597
150 :     rounder_7:
151 :     dd 512, 512
152 :     rounder_2:
153 :     dd 2260, 2260
154 :     rounder_6:
155 :     dd 512, 512
156 :     rounder_3:
157 :     dd 1203, 1203
158 :     rounder_5:
159 :     dd 120, 120
160 : Isibaar 3 %else
161 :    
162 : edgomez 1382 %error invalid SHIFT_INV_ROW
163 : Isibaar 3
164 :     %endif
165 :    
166 : edgomez 1382 ;-----------------------------------------------------------------------------
167 : Isibaar 3 ;
168 :     ; The first stage iDCT 8x8 - inverse DCTs of rows
169 :     ;
170 :     ;-----------------------------------------------------------------------------
171 :     ; The 8-point inverse DCT direct algorithm
172 :     ;-----------------------------------------------------------------------------
173 :     ;
174 :     ; static const short w[32] = {
175 :     ; FIX(cos_4_16), FIX(cos_2_16), FIX(cos_4_16), FIX(cos_6_16),
176 :     ; FIX(cos_4_16), FIX(cos_6_16), -FIX(cos_4_16), -FIX(cos_2_16),
177 :     ; FIX(cos_4_16), -FIX(cos_6_16), -FIX(cos_4_16), FIX(cos_2_16),
178 :     ; FIX(cos_4_16), -FIX(cos_2_16), FIX(cos_4_16), -FIX(cos_6_16),
179 :     ; FIX(cos_1_16), FIX(cos_3_16), FIX(cos_5_16), FIX(cos_7_16),
180 :     ; FIX(cos_3_16), -FIX(cos_7_16), -FIX(cos_1_16), -FIX(cos_5_16),
181 :     ; FIX(cos_5_16), -FIX(cos_1_16), FIX(cos_7_16), FIX(cos_3_16),
182 :     ; FIX(cos_7_16), -FIX(cos_5_16), FIX(cos_3_16), -FIX(cos_1_16) };
183 :     ;
184 :     ; #define DCT_8_INV_ROW(x, y)
185 :     ; {
186 :     ; int a0, a1, a2, a3, b0, b1, b2, b3;
187 :     ;
188 :     ; a0 =x[0]*w[0]+x[2]*w[1]+x[4]*w[2]+x[6]*w[3];
189 :     ; a1 =x[0]*w[4]+x[2]*w[5]+x[4]*w[6]+x[6]*w[7];
190 :     ; a2 = x[0] * w[ 8] + x[2] * w[ 9] + x[4] * w[10] + x[6] * w[11];
191 :     ; a3 = x[0] * w[12] + x[2] * w[13] + x[4] * w[14] + x[6] * w[15];
192 :     ; b0 = x[1] * w[16] + x[3] * w[17] + x[5] * w[18] + x[7] * w[19];
193 :     ; b1 = x[1] * w[20] + x[3] * w[21] + x[5] * w[22] + x[7] * w[23];
194 :     ; b2 = x[1] * w[24] + x[3] * w[25] + x[5] * w[26] + x[7] * w[27];
195 :     ; b3 = x[1] * w[28] + x[3] * w[29] + x[5] * w[30] + x[7] * w[31];
196 :     ;
197 :     ; y[0] = SHIFT_ROUND ( a0 + b0 );
198 :     ; y[1] = SHIFT_ROUND ( a1 + b1 );
199 :     ; y[2] = SHIFT_ROUND ( a2 + b2 );
200 :     ; y[3] = SHIFT_ROUND ( a3 + b3 );
201 :     ; y[4] = SHIFT_ROUND ( a3 - b3 );
202 :     ; y[5] = SHIFT_ROUND ( a2 - b2 );
203 :     ; y[6] = SHIFT_ROUND ( a1 - b1 );
204 :     ; y[7] = SHIFT_ROUND ( a0 - b0 );
205 :     ; }
206 :     ;
207 :     ;-----------------------------------------------------------------------------
208 :     ;
209 :     ; In this implementation the outputs of the iDCT-1D are multiplied
210 :     ; for rows 0,4 - by cos_4_16,
211 :     ; for rows 1,7 - by cos_1_16,
212 :     ; for rows 2,6 - by cos_2_16,
213 :     ; for rows 3,5 - by cos_3_16
214 :     ; and are shifted to the left for better accuracy
215 :     ;
216 :     ; For the constants used,
217 :     ; FIX(float_const) = (short) (float_const * (1<<15) + 0.5)
218 :     ;
219 : edgomez 1382 ;-----------------------------------------------------------------------------
220 : Isibaar 3
221 : edgomez 1382 ;-----------------------------------------------------------------------------
222 :     ; Tables for mmx processors
223 :     ;-----------------------------------------------------------------------------
224 : Isibaar 3
225 :     ; Table for rows 0,4 - constants are multiplied by cos_4_16
226 : edgomez 1382 tab_i_04_mmx:
227 :     dw 16384, 16384, 16384, -16384 ; movq-> w06 w04 w02 w00
228 :     dw 21407, 8867, 8867, -21407 ; w07 w05 w03 w01
229 :     dw 16384, -16384, 16384, 16384 ; w14 w12 w10 w08
230 :     dw -8867, 21407, -21407, -8867 ; w15 w13 w11 w09
231 :     dw 22725, 12873, 19266, -22725 ; w22 w20 w18 w16
232 :     dw 19266, 4520, -4520, -12873 ; w23 w21 w19 w17
233 :     dw 12873, 4520, 4520, 19266 ; w30 w28 w26 w24
234 :     dw -22725, 19266, -12873, -22725 ; w31 w29 w27 w25
235 : Isibaar 3
236 :     ; Table for rows 1,7 - constants are multiplied by cos_1_16
237 : edgomez 1382 tab_i_17_mmx:
238 :     dw 22725, 22725, 22725, -22725 ; movq-> w06 w04 w02 w00
239 :     dw 29692, 12299, 12299, -29692 ; w07 w05 w03 w01
240 :     dw 22725, -22725, 22725, 22725 ; w14 w12 w10 w08
241 :     dw -12299, 29692, -29692, -12299 ; w15 w13 w11 w09
242 :     dw 31521, 17855, 26722, -31521 ; w22 w20 w18 w16
243 :     dw 26722, 6270, -6270, -17855 ; w23 w21 w19 w17
244 :     dw 17855, 6270, 6270, 26722 ; w30 w28 w26 w24
245 :     dw -31521, 26722, -17855, -31521 ; w31 w29 w27 w25
246 : Isibaar 3
247 :     ; Table for rows 2,6 - constants are multiplied by cos_2_16
248 : edgomez 1382 tab_i_26_mmx:
249 :     dw 21407, 21407, 21407, -21407 ; movq-> w06 w04 w02 w00
250 :     dw 27969, 11585, 11585, -27969 ; w07 w05 w03 w01
251 :     dw 21407, -21407, 21407, 21407 ; w14 w12 w10 w08
252 :     dw -11585, 27969, -27969, -11585 ; w15 w13 w11 w09
253 :     dw 29692, 16819, 25172, -29692 ; w22 w20 w18 w16
254 :     dw 25172, 5906, -5906, -16819 ; w23 w21 w19 w17
255 :     dw 16819, 5906, 5906, 25172 ; w30 w28 w26 w24
256 :     dw -29692, 25172, -16819, -29692 ; w31 w29 w27 w25
257 : Isibaar 3
258 :     ; Table for rows 3,5 - constants are multiplied by cos_3_16
259 : edgomez 1382 tab_i_35_mmx:
260 :     dw 19266, 19266, 19266, -19266 ; movq-> w06 w04 w02 w00
261 :     dw 25172, 10426, 10426, -25172 ; w07 w05 w03 w01
262 :     dw 19266, -19266, 19266, 19266 ; w14 w12 w10 w08
263 :     dw -10426, 25172, -25172, -10426 ; w15 w13 w11 w09
264 :     dw 26722, 15137, 22654, -26722 ; w22 w20 w18 w16
265 :     dw 22654, 5315, -5315, -15137 ; w23 w21 w19 w17
266 :     dw 15137, 5315, 5315, 22654 ; w30 w28 w26 w24
267 :     dw -26722, 22654, -15137, -26722 ; w31 w29 w27 w25
268 : Isibaar 3
269 :     ;-----------------------------------------------------------------------------
270 : edgomez 1382 ; Tables for xmm processors
271 :     ;-----------------------------------------------------------------------------
272 : Isibaar 3
273 :     ; %3 for rows 0,4 - constants are multiplied by cos_4_16
274 : edgomez 1382 tab_i_04_xmm:
275 :     dw 16384, 21407, 16384, 8867 ; movq-> w05 w04 w01 w00
276 :     dw 16384, 8867, -16384, -21407 ; w07 w06 w03 w02
277 :     dw 16384, -8867, 16384, -21407 ; w13 w12 w09 w08
278 :     dw -16384, 21407, 16384, -8867 ; w15 w14 w11 w10
279 :     dw 22725, 19266, 19266, -4520 ; w21 w20 w17 w16
280 :     dw 12873, 4520, -22725, -12873 ; w23 w22 w19 w18
281 :     dw 12873, -22725, 4520, -12873 ; w29 w28 w25 w24
282 :     dw 4520, 19266, 19266, -22725 ; w31 w30 w27 w26
283 : Isibaar 3
284 :     ; %3 for rows 1,7 - constants are multiplied by cos_1_16
285 : edgomez 1382 tab_i_17_xmm:
286 :     dw 22725, 29692, 22725, 12299 ; movq-> w05 w04 w01 w00
287 :     dw 22725, 12299, -22725, -29692 ; w07 w06 w03 w02
288 :     dw 22725, -12299, 22725, -29692 ; w13 w12 w09 w08
289 :     dw -22725, 29692, 22725, -12299 ; w15 w14 w11 w10
290 :     dw 31521, 26722, 26722, -6270 ; w21 w20 w17 w16
291 :     dw 17855, 6270, -31521, -17855 ; w23 w22 w19 w18
292 :     dw 17855, -31521, 6270, -17855 ; w29 w28 w25 w24
293 :     dw 6270, 26722, 26722, -31521 ; w31 w30 w27 w26
294 : Isibaar 3
295 :     ; %3 for rows 2,6 - constants are multiplied by cos_2_16
296 : edgomez 1382 tab_i_26_xmm:
297 :     dw 21407, 27969, 21407, 11585 ; movq-> w05 w04 w01 w00
298 :     dw 21407, 11585, -21407, -27969 ; w07 w06 w03 w02
299 :     dw 21407, -11585, 21407, -27969 ; w13 w12 w09 w08
300 :     dw -21407, 27969, 21407, -11585 ; w15 w14 w11 w10
301 :     dw 29692, 25172, 25172, -5906 ; w21 w20 w17 w16
302 :     dw 16819, 5906, -29692, -16819 ; w23 w22 w19 w18
303 :     dw 16819, -29692, 5906, -16819 ; w29 w28 w25 w24
304 :     dw 5906, 25172, 25172, -29692 ; w31 w30 w27 w26
305 : Isibaar 3
306 :     ; %3 for rows 3,5 - constants are multiplied by cos_3_16
307 : edgomez 1382 tab_i_35_xmm:
308 :     dw 19266, 25172, 19266, 10426 ; movq-> w05 w04 w01 w00
309 :     dw 19266, 10426, -19266, -25172 ; w07 w06 w03 w02
310 :     dw 19266, -10426, 19266, -25172 ; w13 w12 w09 w08
311 :     dw -19266, 25172, 19266, -10426 ; w15 w14 w11 w10
312 :     dw 26722, 22654, 22654, -5315 ; w21 w20 w17 w16
313 :     dw 15137, 5315, -26722, -15137 ; w23 w22 w19 w18
314 :     dw 15137, -26722, 5315, -15137 ; w29 w28 w25 w24
315 :     dw 5315, 22654, 22654, -26722 ; w31 w30 w27 w26
316 : Isibaar 3
317 : edgomez 1382 ;=============================================================================
318 :     ; Helper macros for the code
319 :     ;=============================================================================
320 : Isibaar 3
321 :     ;-----------------------------------------------------------------------------
322 : edgomez 1382 ; DCT_8_INV_ROW_MMX INP, OUT, TABLE, ROUNDER
323 :     ;-----------------------------------------------------------------------------
324 : Isibaar 3
325 : edgomez 1382 %macro DCT_8_INV_ROW_MMX 4
326 :     movq mm0, [%1] ; 0 ; x3 x2 x1 x0
327 :     movq mm1, [%1+8] ; 1 ; x7 x6 x5 x4
328 :     movq mm2, mm0 ; 2 ; x3 x2 x1 x0
329 :     movq mm3, [%3] ; 3 ; w06 w04 w02 w00
330 :     punpcklwd mm0, mm1 ; x5 x1 x4 x0
331 :     movq mm5, mm0 ; 5 ; x5 x1 x4 x0
332 :     punpckldq mm0, mm0 ; x4 x0 x4 x0
333 :     movq mm4, [%3+8] ; 4 ; w07 w05 w03 w01
334 :     punpckhwd mm2, mm1 ; 1 ; x7 x3 x6 x2
335 :     pmaddwd mm3, mm0 ; x4*w06+x0*w04 x4*w02+x0*w00
336 :     movq mm6, mm2 ; 6 ; x7 x3 x6 x2
337 :     movq mm1, [%3+32] ; 1 ; w22 w20 w18 w16
338 :     punpckldq mm2, mm2 ; x6 x2 x6 x2
339 :     pmaddwd mm4, mm2 ; x6*w07+x2*w05 x6*w03+x2*w01
340 :     punpckhdq mm5, mm5 ; x5 x1 x5 x1
341 :     pmaddwd mm0, [%3+16] ; x4*w14+x0*w12 x4*w10+x0*w08
342 :     punpckhdq mm6, mm6 ; x7 x3 x7 x3
343 :     movq mm7, [%3+40] ; 7 ; w23 w21 w19 w17
344 :     pmaddwd mm1, mm5 ; x5*w22+x1*w20 x5*w18+x1*w16
345 :     paddd mm3, [%4] ; +%4
346 :     pmaddwd mm7, mm6 ; x7*w23+x3*w21 x7*w19+x3*w17
347 :     pmaddwd mm2, [%3+24] ; x6*w15+x2*w13 x6*w11+x2*w09
348 :     paddd mm3, mm4 ; 4 ; a1=sum(even1) a0=sum(even0)
349 :     pmaddwd mm5, [%3+48] ; x5*w30+x1*w28 x5*w26+x1*w24
350 :     movq mm4, mm3 ; 4 ; a1 a0
351 :     pmaddwd mm6, [%3+56] ; x7*w31+x3*w29 x7*w27+x3*w25
352 :     paddd mm1, mm7 ; 7 ; b1=sum(odd1) b0=sum(odd0)
353 :     paddd mm0, [%4] ; +%4
354 :     psubd mm3, mm1 ; a1-b1 a0-b0
355 :     psrad mm3, SHIFT_INV_ROW ; y6=a1-b1 y7=a0-b0
356 :     paddd mm1, mm4 ; 4 ; a1+b1 a0+b0
357 :     paddd mm0, mm2 ; 2 ; a3=sum(even3) a2=sum(even2)
358 :     psrad mm1, SHIFT_INV_ROW ; y1=a1+b1 y0=a0+b0
359 :     paddd mm5, mm6 ; 6 ; b3=sum(odd3) b2=sum(odd2)
360 :     movq mm4, mm0 ; 4 ; a3 a2
361 :     paddd mm0, mm5 ; a3+b3 a2+b2
362 :     psubd mm4, mm5 ; 5 ; a3-b3 a2-b2
363 :     psrad mm0, SHIFT_INV_ROW ; y3=a3+b3 y2=a2+b2
364 :     psrad mm4, SHIFT_INV_ROW ; y4=a3-b3 y5=a2-b2
365 :     packssdw mm1, mm0 ; 0 ; y3 y2 y1 y0
366 :     packssdw mm4, mm3 ; 3 ; y6 y7 y4 y5
367 :     movq mm7, mm4 ; 7 ; y6 y7 y4 y5
368 :     psrld mm4, 16 ; 0 y6 0 y4
369 :     pslld mm7, 16 ; y7 0 y5 0
370 :     movq [%2], mm1 ; 1 ; save y3 y2 y1 y0
371 :     por mm7, mm4 ; 4 ; y7 y6 y5 y4
372 :     movq [%2+8], mm7 ; 7 ; save y7 y6 y5 y4
373 :     %endmacro
374 : Isibaar 3
375 : edgomez 1382 ;-----------------------------------------------------------------------------
376 :     ; DCT_8_INV_ROW_XMM INP, OUT, TABLE, ROUNDER
377 :     ;-----------------------------------------------------------------------------
378 : Isibaar 3
379 : edgomez 1382 %macro DCT_8_INV_ROW_XMM 4
380 :     movq mm0, [%1] ; 0 ; x3 x2 x1 x0
381 :     movq mm1, [%1+8] ; 1 ; x7 x6 x5 x4
382 :     movq mm2, mm0 ; 2 ; x3 x2 x1 x0
383 :     movq mm3, [%3] ; 3 ; w05 w04 w01 w00
384 :     pshufw mm0, mm0, 10001000b ; x2 x0 x2 x0
385 :     movq mm4, [%3+8] ; 4 ; w07 w06 w03 w02
386 :     movq mm5, mm1 ; 5 ; x7 x6 x5 x4
387 :     pmaddwd mm3, mm0 ; x2*w05+x0*w04 x2*w01+x0*w00
388 :     movq mm6, [%3+32] ; 6 ; w21 w20 w17 w16
389 :     pshufw mm1, mm1, 10001000b ; x6 x4 x6 x4
390 :     pmaddwd mm4, mm1 ; x6*w07+x4*w06 x6*w03+x4*w02
391 :     movq mm7, [%3+40] ; 7 ; w23 w22 w19 w18
392 :     pshufw mm2, mm2, 11011101b ; x3 x1 x3 x1
393 :     pmaddwd mm6, mm2 ; x3*w21+x1*w20 x3*w17+x1*w16
394 :     pshufw mm5, mm5, 11011101b ; x7 x5 x7 x5
395 :     pmaddwd mm7, mm5 ; x7*w23+x5*w22 x7*w19+x5*w18
396 :     paddd mm3, [%4] ; +%4
397 :     pmaddwd mm0, [%3+16] ; x2*w13+x0*w12 x2*w09+x0*w08
398 :     paddd mm3, mm4 ; 4 ; a1=sum(even1) a0=sum(even0)
399 :     pmaddwd mm1, [%3+24] ; x6*w15+x4*w14 x6*w11+x4*w10
400 :     movq mm4, mm3 ; 4 ; a1 a0
401 :     pmaddwd mm2, [%3+48] ; x3*w29+x1*w28 x3*w25+x1*w24
402 :     paddd mm6, mm7 ; 7 ; b1=sum(odd1) b0=sum(odd0)
403 :     pmaddwd mm5, [%3+56] ; x7*w31+x5*w30 x7*w27+x5*w26
404 :     paddd mm3, mm6 ; a1+b1 a0+b0
405 :     paddd mm0, [%4] ; +%4
406 :     psrad mm3, SHIFT_INV_ROW ; y1=a1+b1 y0=a0+b0
407 :     paddd mm0, mm1 ; 1 ; a3=sum(even3) a2=sum(even2)
408 :     psubd mm4, mm6 ; 6 ; a1-b1 a0-b0
409 :     movq mm7, mm0 ; 7 ; a3 a2
410 :     paddd mm2, mm5 ; 5 ; b3=sum(odd3) b2=sum(odd2)
411 :     paddd mm0, mm2 ; a3+b3 a2+b2
412 :     psrad mm4, SHIFT_INV_ROW ; y6=a1-b1 y7=a0-b0
413 :     psubd mm7, mm2 ; 2 ; a3-b3 a2-b2
414 :     psrad mm0, SHIFT_INV_ROW ; y3=a3+b3 y2=a2+b2
415 :     psrad mm7, SHIFT_INV_ROW ; y4=a3-b3 y5=a2-b2
416 :     packssdw mm3, mm0 ; 0 ; y3 y2 y1 y0
417 :     packssdw mm7, mm4 ; 4 ; y6 y7 y4 y5
418 :     movq [%2], mm3 ; 3 ; save y3 y2 y1 y0
419 :     pshufw mm7, mm7, 10110001b ; y7 y6 y5 y4
420 :     movq [%2+8], mm7 ; 7 ; save y7 y6 y5 y4
421 : Isibaar 3 %endmacro
422 :    
423 : edgomez 1382 ;-----------------------------------------------------------------------------
424 : Isibaar 3 ;
425 :     ; The first stage DCT 8x8 - forward DCTs of columns
426 :     ;
427 :     ; The %2puts are multiplied
428 :     ; for rows 0,4 - on cos_4_16,
429 :     ; for rows 1,7 - on cos_1_16,
430 :     ; for rows 2,6 - on cos_2_16,
431 :     ; for rows 3,5 - on cos_3_16
432 :     ; and are shifted to the left for rise of accuracy
433 :     ;
434 :     ;-----------------------------------------------------------------------------
435 :     ;
436 :     ; The 8-point scaled forward DCT algorithm (26a8m)
437 :     ;
438 :     ;-----------------------------------------------------------------------------
439 :     ;
440 :     ; #define DCT_8_FRW_COL(x, y)
441 :     ;{
442 :     ; short t0, t1, t2, t3, t4, t5, t6, t7;
443 :     ; short tp03, tm03, tp12, tm12, tp65, tm65;
444 :     ; short tp465, tm465, tp765, tm765;
445 :     ;
446 :     ; t0 = LEFT_SHIFT ( x[0] + x[7] );
447 :     ; t1 = LEFT_SHIFT ( x[1] + x[6] );
448 :     ; t2 = LEFT_SHIFT ( x[2] + x[5] );
449 :     ; t3 = LEFT_SHIFT ( x[3] + x[4] );
450 :     ; t4 = LEFT_SHIFT ( x[3] - x[4] );
451 :     ; t5 = LEFT_SHIFT ( x[2] - x[5] );
452 :     ; t6 = LEFT_SHIFT ( x[1] - x[6] );
453 :     ; t7 = LEFT_SHIFT ( x[0] - x[7] );
454 :     ;
455 :     ; tp03 = t0 + t3;
456 :     ; tm03 = t0 - t3;
457 :     ; tp12 = t1 + t2;
458 :     ; tm12 = t1 - t2;
459 :     ;
460 :     ; y[0] = tp03 + tp12;
461 :     ; y[4] = tp03 - tp12;
462 :     ;
463 :     ; y[2] = tm03 + tm12 * tg_2_16;
464 :     ; y[6] = tm03 * tg_2_16 - tm12;
465 :     ;
466 :     ; tp65 =(t6 +t5 )*cos_4_16;
467 :     ; tm65 =(t6 -t5 )*cos_4_16;
468 :     ;
469 :     ; tp765 = t7 + tp65;
470 :     ; tm765 = t7 - tp65;
471 :     ; tp465 = t4 + tm65;
472 :     ; tm465 = t4 - tm65;
473 :     ;
474 :     ; y[1] = tp765 + tp465 * tg_1_16;
475 :     ; y[7] = tp765 * tg_1_16 - tp465;
476 :     ; y[5] = tm765 * tg_3_16 + tm465;
477 :     ; y[3] = tm765 - tm465 * tg_3_16;
478 :     ;}
479 :     ;
480 : edgomez 1382 ;-----------------------------------------------------------------------------
481 : Isibaar 3
482 : edgomez 1382 ;-----------------------------------------------------------------------------
483 : Isibaar 3 ; DCT_8_INV_COL_4 INP,OUT
484 : edgomez 1382 ;-----------------------------------------------------------------------------
485 : Isibaar 3
486 : edgomez 1382 %macro DCT_8_INV_COL 2
487 :     movq mm0, [tg_3_16]
488 :     movq mm3, [%1+16*3]
489 :     movq mm1, mm0 ; tg_3_16
490 :     movq mm5, [%1+16*5]
491 :     pmulhw mm0, mm3 ; x3*(tg_3_16-1)
492 :     movq mm4, [tg_1_16]
493 :     pmulhw mm1, mm5 ; x5*(tg_3_16-1)
494 :     movq mm7, [%1+16*7]
495 :     movq mm2, mm4 ; tg_1_16
496 :     movq mm6, [%1+16*1]
497 :     pmulhw mm4, mm7 ; x7*tg_1_16
498 :     paddsw mm0, mm3 ; x3*tg_3_16
499 :     pmulhw mm2, mm6 ; x1*tg_1_16
500 :     paddsw mm1, mm3 ; x3+x5*(tg_3_16-1)
501 :     psubsw mm0, mm5 ; x3*tg_3_16-x5 = tm35
502 :     movq mm3, [ocos_4_16]
503 :     paddsw mm1, mm5 ; x3+x5*tg_3_16 = tp35
504 :     paddsw mm4, mm6 ; x1+tg_1_16*x7 = tp17
505 :     psubsw mm2, mm7 ; x1*tg_1_16-x7 = tm17
506 :     movq mm5, mm4 ; tp17
507 :     movq mm6, mm2 ; tm17
508 :     paddsw mm5, mm1 ; tp17+tp35 = b0
509 :     psubsw mm6, mm0 ; tm17-tm35 = b3
510 :     psubsw mm4, mm1 ; tp17-tp35 = t1
511 :     paddsw mm2, mm0 ; tm17+tm35 = t2
512 :     movq mm7, [tg_2_16]
513 :     movq mm1, mm4 ; t1
514 :     ; movq [SCRATCH+0], mm5 ; save b0
515 :     movq [%2+3*16], mm5 ; save b0
516 :     paddsw mm1, mm2 ; t1+t2
517 :     ; movq [SCRATCH+8], mm6 ; save b3
518 :     movq [%2+5*16], mm6 ; save b3
519 :     psubsw mm4, mm2 ; t1-t2
520 :     movq mm5, [%1+2*16]
521 :     movq mm0, mm7 ; tg_2_16
522 :     movq mm6, [%1+6*16]
523 :     pmulhw mm0, mm5 ; x2*tg_2_16
524 :     pmulhw mm7, mm6 ; x6*tg_2_16
525 : Isibaar 3 ; slot
526 : edgomez 1382 pmulhw mm1, mm3 ; ocos_4_16*(t1+t2) = b1/2
527 : Isibaar 3 ; slot
528 : edgomez 1382 movq mm2, [%1+0*16]
529 :     pmulhw mm4, mm3 ; ocos_4_16*(t1-t2) = b2/2
530 :     psubsw mm0, mm6 ; t2*tg_2_16-x6 = tm26
531 :     movq mm3, mm2 ; x0
532 :     movq mm6, [%1+4*16]
533 :     paddsw mm7, mm5 ; x2+x6*tg_2_16 = tp26
534 :     paddsw mm2, mm6 ; x0+x4 = tp04
535 :     psubsw mm3, mm6 ; x0-x4 = tm04
536 :     movq mm5, mm2 ; tp04
537 :     movq mm6, mm3 ; tm04
538 :     psubsw mm2, mm7 ; tp04-tp26 = a3
539 :     paddsw mm3, mm0 ; tm04+tm26 = a1
540 :     paddsw mm1, mm1 ; b1
541 :     paddsw mm4, mm4 ; b2
542 :     paddsw mm5, mm7 ; tp04+tp26 = a0
543 :     psubsw mm6, mm0 ; tm04-tm26 = a2
544 :     movq mm7, mm3 ; a1
545 :     movq mm0, mm6 ; a2
546 :     paddsw mm3, mm1 ; a1+b1
547 :     paddsw mm6, mm4 ; a2+b2
548 :     psraw mm3, SHIFT_INV_COL ; dst1
549 :     psubsw mm7, mm1 ; a1-b1
550 :     psraw mm6, SHIFT_INV_COL ; dst2
551 :     psubsw mm0, mm4 ; a2-b2
552 :     ; movq mm1, [SCRATCH+0] ; load b0
553 :     movq mm1, [%2+3*16] ; load b0
554 :     psraw mm7, SHIFT_INV_COL ; dst6
555 :     movq mm4, mm5 ; a0
556 :     psraw mm0, SHIFT_INV_COL ; dst5
557 :     movq [%2+1*16], mm3
558 :     paddsw mm5, mm1 ; a0+b0
559 :     movq [%2+2*16], mm6
560 :     psubsw mm4, mm1 ; a0-b0
561 :     ; movq mm3, [SCRATCH+8] ; load b3
562 :     movq mm3, [%2+5*16] ; load b3
563 :     psraw mm5, SHIFT_INV_COL ; dst0
564 :     movq mm6, mm2 ; a3
565 :     psraw mm4, SHIFT_INV_COL ; dst7
566 :     movq [%2+5*16], mm0
567 :     paddsw mm2, mm3 ; a3+b3
568 :     movq [%2+6*16], mm7
569 :     psubsw mm6, mm3 ; a3-b3
570 :     movq [%2+0*16], mm5
571 :     psraw mm2, SHIFT_INV_COL ; dst3
572 :     movq [%2+7*16], mm4
573 :     psraw mm6, SHIFT_INV_COL ; dst4
574 :     movq [%2+3*16], mm2
575 :     movq [%2+4*16], mm6
576 : Isibaar 3 %endmacro
577 :    
578 :     ;=============================================================================
579 : edgomez 1382 ; Code
580 : Isibaar 3 ;=============================================================================
581 :    
582 : edgomez 1382 SECTION .text
583 : Isibaar 3
584 : edgomez 1382 cglobal idct_mmx
585 : Isibaar 3 cglobal idct_xmm
586 :    
587 : edgomez 1382 ;-----------------------------------------------------------------------------
588 :     ; void idct_mmx(uint16_t block[64]);
589 :     ;-----------------------------------------------------------------------------
590 : Isibaar 3
591 : edgomez 1382 ALIGN 16
592 :     idct_mmx:
593 :     mov eax, dword [esp + 4]
594 : Isibaar 3
595 : edgomez 1382 ;; Process each row
596 :     DCT_8_INV_ROW_MMX eax+0*16, eax+0*16, tab_i_04_mmx, rounder_0
597 :     DCT_8_INV_ROW_MMX eax+1*16, eax+1*16, tab_i_17_mmx, rounder_1
598 :     DCT_8_INV_ROW_MMX eax+2*16, eax+2*16, tab_i_26_mmx, rounder_2
599 :     DCT_8_INV_ROW_MMX eax+3*16, eax+3*16, tab_i_35_mmx, rounder_3
600 :     DCT_8_INV_ROW_MMX eax+4*16, eax+4*16, tab_i_04_mmx, rounder_4
601 :     DCT_8_INV_ROW_MMX eax+5*16, eax+5*16, tab_i_35_mmx, rounder_5
602 :     DCT_8_INV_ROW_MMX eax+6*16, eax+6*16, tab_i_26_mmx, rounder_6
603 :     DCT_8_INV_ROW_MMX eax+7*16, eax+7*16, tab_i_17_mmx, rounder_7
604 : Isibaar 154
605 : edgomez 1382 ;; Process the columns (4 at a time)
606 :     DCT_8_INV_COL eax+0, eax+0
607 :     DCT_8_INV_COL eax+8, eax+8
608 : Isibaar 154
609 : edgomez 1382 ret
610 : Isibaar 1793 ENDFUNC
611 : Isibaar 154
612 : edgomez 1382 ;-----------------------------------------------------------------------------
613 :     ; void idct_xmm(uint16_t block[64]);
614 :     ;-----------------------------------------------------------------------------
615 : Isibaar 154
616 : edgomez 1382 ALIGN 16
617 :     idct_xmm:
618 :     mov eax, dword [esp + 4]
619 : Isibaar 154
620 : edgomez 1382 ;; Process each row
621 :     DCT_8_INV_ROW_XMM eax+0*16, eax+0*16, tab_i_04_xmm, rounder_0
622 :     DCT_8_INV_ROW_XMM eax+1*16, eax+1*16, tab_i_17_xmm, rounder_1
623 :     DCT_8_INV_ROW_XMM eax+2*16, eax+2*16, tab_i_26_xmm, rounder_2
624 :     DCT_8_INV_ROW_XMM eax+3*16, eax+3*16, tab_i_35_xmm, rounder_3
625 :     DCT_8_INV_ROW_XMM eax+4*16, eax+4*16, tab_i_04_xmm, rounder_4
626 :     DCT_8_INV_ROW_XMM eax+5*16, eax+5*16, tab_i_35_xmm, rounder_5
627 :     DCT_8_INV_ROW_XMM eax+6*16, eax+6*16, tab_i_26_xmm, rounder_6
628 :     DCT_8_INV_ROW_XMM eax+7*16, eax+7*16, tab_i_17_xmm, rounder_7
629 : Isibaar 154
630 : edgomez 1382 ;; Process the columns (4 at a time)
631 :     DCT_8_INV_COL eax+0, eax+0
632 :     DCT_8_INV_COL eax+8, eax+8
633 : Isibaar 154
634 : edgomez 1382 ret
635 : Isibaar 1793 ENDFUNC
636 : edgomez 1540
637 : Isibaar 1790
638 :     %ifidn __OUTPUT_FORMAT__,elf
639 :     section ".note.GNU-stack" noalloc noexec nowrite progbits
640 :     %endif
641 :    
No admin address has been configured
 ViewVC Help
Powered by ViewVC 1.0.4