[svn] / trunk / xvidcore / src / dct / x86_asm / idct_mmx.asm Repository:
ViewVC logotype

Annotation of /trunk/xvidcore/src/dct/x86_asm/idct_mmx.asm

Parent Directory Parent Directory | Revision Log Revision Log

Revision 1382 - (view) (download)

1 : edgomez 1382 ;/****************************************************************************
2 :     ; *
3 :     ; * XVID MPEG-4 VIDEO CODEC
4 :     ; * - MMX and XMM forward discrete cosine transform -
5 :     ; *
6 :     ; * Copyright(C) 2001 Peter Ross <pross@xvid.org>
7 :     ; *
8 :     ; * This program is free software; you can redistribute it and/or modify it
9 :     ; * under the terms of the GNU General Public License as published by
10 :     ; * the Free Software Foundation; either version 2 of the License, or
11 :     ; * (at your option) any later version.
12 :     ; *
13 :     ; * This program is distributed in the hope that it will be useful,
14 :     ; * but WITHOUT ANY WARRANTY; without even the implied warranty of
15 :     ; * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
16 :     ; * GNU General Public License for more details.
17 :     ; *
18 :     ; * You should have received a copy of the GNU General Public License
19 :     ; * along with this program; if not, write to the Free Software
20 :     ; * Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307 USA
21 :     ; *
22 :     ; * $Id: idct_mmx.asm,v 1.7 2004-03-22 22:36:23 edgomez Exp $
23 :     ; *
24 :     ; ***************************************************************************/
25 :    
26 :     ; ****************************************************************************
27 :     ;
28 : edgomez 851 ; Originally provided by Intel at AP-922
29 :     ; http://developer.intel.com/vtune/cbts/strmsimd/922down.htm
30 :     ; (See more app notes at http://developer.intel.com/vtune/cbts/strmsimd/appnotes.htm)
31 :     ; but in a limited edition.
32 :     ; New macro implements a column part for precise iDCT
33 : edgomez 1382 ; The routine precision now satisfies IEEE standard 1180-1990.
34 : edgomez 851 ;
35 : edgomez 1382 ; Copyright(C) 2000-2001 Peter Gubanov <peter@elecard.net.ru>
36 :     ; Rounding trick Copyright(C) 2000 Michel Lespinasse <walken@zoy.org>
37 : edgomez 851 ;
38 :     ; http://www.elecard.com/peter/idct.html
39 :     ; http://www.linuxvideo.org/mpeg2dec/
40 :     ;
41 : edgomez 1382 ; ***************************************************************************/
42 : Isibaar 3 ;
43 :     ; These examples contain code fragments for first stage iDCT 8x8
44 :     ; (for rows) and first stage DCT 8x8 (for columns)
45 :     ;
46 :    
47 : edgomez 1382 BITS 32
48 : Isibaar 3
49 : edgomez 1382 ;=============================================================================
50 :     ; Macros and other preprocessor constants
51 :     ;=============================================================================
52 :    
53 :     %macro cglobal 1
54 : Isibaar 3 %ifdef PREFIX
55 : edgomez 1382 global _%1
56 : Isibaar 3 %define %1 _%1
57 :     %else
58 :     global %1
59 :     %endif
60 :     %endmacro
61 :    
62 : edgomez 1382 %define BITS_INV_ACC 5 ; 4 or 5 for IEEE
63 : Isibaar 3 %define SHIFT_INV_ROW 16 - BITS_INV_ACC
64 :     %define SHIFT_INV_COL 1 + BITS_INV_ACC
65 :     %define RND_INV_ROW 1024 * (6 - BITS_INV_ACC) ; 1 << (SHIFT_INV_ROW-1)
66 :     %define RND_INV_COL 16 * (BITS_INV_ACC - 3) ; 1 << (SHIFT_INV_COL-1)
67 : edgomez 1382 %define RND_INV_CORR RND_INV_COL - 1 ; correction -1.0 and round
68 : Isibaar 3
69 : edgomez 1382 %define BITS_FRW_ACC 3 ; 2 or 3 for accuracy
70 : Isibaar 3 %define SHIFT_FRW_COL BITS_FRW_ACC
71 :     %define SHIFT_FRW_ROW BITS_FRW_ACC + 17
72 : edgomez 1382 %define RND_FRW_ROW 262144*(BITS_FRW_ACC - 1) ; 1 << (SHIFT_FRW_ROW-1)
73 : Isibaar 3
74 : edgomez 1382 ;=============================================================================
75 :     ; Local Data (Read Only)
76 :     ;=============================================================================
77 :    
78 : suxen_drol 207 %ifdef FORMAT_COFF
79 : edgomez 1382 SECTION .rodata data
80 : suxen_drol 207 %else
81 : edgomez 1382 SECTION .rodata data align=16
82 : suxen_drol 207 %endif
83 : Isibaar 3
84 : edgomez 1382 ;-----------------------------------------------------------------------------
85 :     ; Various memory constants (trigonometric values or rounding values)
86 :     ;-----------------------------------------------------------------------------
87 : Isibaar 3
88 : edgomez 1382 ALIGN 16
89 :     one_corr:
90 :     dw 1, 1, 1, 1
91 :     round_inv_row:
92 :     dd RND_INV_ROW, RND_INV_ROW
93 :     round_inv_col:
94 :     dw RND_INV_COL, RND_INV_COL, RND_INV_COL, RND_INV_COL
95 :     round_inv_corr:
96 :     dw RND_INV_CORR, RND_INV_CORR, RND_INV_CORR, RND_INV_CORR
97 :     round_frw_row:
98 :     dd RND_FRW_ROW, RND_FRW_ROW
99 :     tg_1_16:
100 :     dw 13036, 13036, 13036, 13036 ; tg * (2<<16) + 0.5
101 :     tg_2_16:
102 :     dw 27146, 27146, 27146, 27146 ; tg * (2<<16) + 0.5
103 :     tg_3_16:
104 :     dw -21746, -21746, -21746, -21746 ; tg * (2<<16) + 0.5
105 :     cos_4_16:
106 :     dw -19195, -19195, -19195, -19195 ; cos * (2<<16) + 0.5
107 :     ocos_4_16:
108 :     dw 23170, 23170, 23170, 23170 ; cos * (2<<15) + 0.5
109 :     otg_3_16:
110 :     dw 21895, 21895, 21895, 21895 ; tg * (2<<16) + 0.5
111 : Isibaar 3
112 :     %if SHIFT_INV_ROW == 12 ; assume SHIFT_INV_ROW == 12
113 : edgomez 1382 rounder_0:
114 :     dd 65536, 65536
115 :     rounder_4:
116 :     dd 0, 0
117 :     rounder_1:
118 :     dd 7195, 7195
119 :     rounder_7
120 :     dd 1024, 1024
121 :     rounder_2:
122 :     dd 4520, 4520
123 :     rounder_6:
124 :     dd 1024, 1024
125 :     rounder_3:
126 :     dd 2407, 2407
127 :     rounder_5:
128 :     dd 240, 240
129 : Isibaar 3
130 :     %elif SHIFT_INV_ROW == 11 ; assume SHIFT_INV_ROW == 11
131 : edgomez 1382 rounder_0:
132 :     dd 65536, 65536
133 :     rounder_4:
134 :     dd 0, 0
135 :     rounder_1:
136 :     dd 3597, 3597
137 :     rounder_7:
138 :     dd 512, 512
139 :     rounder_2:
140 :     dd 2260, 2260
141 :     rounder_6:
142 :     dd 512, 512
143 :     rounder_3:
144 :     dd 1203, 1203
145 :     rounder_5:
146 :     dd 120, 120
147 : Isibaar 3 %else
148 :    
149 : edgomez 1382 %error invalid SHIFT_INV_ROW
150 : Isibaar 3
151 :     %endif
152 :    
153 : edgomez 1382 ;-----------------------------------------------------------------------------
154 : Isibaar 3 ;
155 :     ; The first stage iDCT 8x8 - inverse DCTs of rows
156 :     ;
157 :     ;-----------------------------------------------------------------------------
158 :     ; The 8-point inverse DCT direct algorithm
159 :     ;-----------------------------------------------------------------------------
160 :     ;
161 :     ; static const short w[32] = {
162 :     ; FIX(cos_4_16), FIX(cos_2_16), FIX(cos_4_16), FIX(cos_6_16),
163 :     ; FIX(cos_4_16), FIX(cos_6_16), -FIX(cos_4_16), -FIX(cos_2_16),
164 :     ; FIX(cos_4_16), -FIX(cos_6_16), -FIX(cos_4_16), FIX(cos_2_16),
165 :     ; FIX(cos_4_16), -FIX(cos_2_16), FIX(cos_4_16), -FIX(cos_6_16),
166 :     ; FIX(cos_1_16), FIX(cos_3_16), FIX(cos_5_16), FIX(cos_7_16),
167 :     ; FIX(cos_3_16), -FIX(cos_7_16), -FIX(cos_1_16), -FIX(cos_5_16),
168 :     ; FIX(cos_5_16), -FIX(cos_1_16), FIX(cos_7_16), FIX(cos_3_16),
169 :     ; FIX(cos_7_16), -FIX(cos_5_16), FIX(cos_3_16), -FIX(cos_1_16) };
170 :     ;
171 :     ; #define DCT_8_INV_ROW(x, y)
172 :     ; {
173 :     ; int a0, a1, a2, a3, b0, b1, b2, b3;
174 :     ;
175 :     ; a0 =x[0]*w[0]+x[2]*w[1]+x[4]*w[2]+x[6]*w[3];
176 :     ; a1 =x[0]*w[4]+x[2]*w[5]+x[4]*w[6]+x[6]*w[7];
177 :     ; a2 = x[0] * w[ 8] + x[2] * w[ 9] + x[4] * w[10] + x[6] * w[11];
178 :     ; a3 = x[0] * w[12] + x[2] * w[13] + x[4] * w[14] + x[6] * w[15];
179 :     ; b0 = x[1] * w[16] + x[3] * w[17] + x[5] * w[18] + x[7] * w[19];
180 :     ; b1 = x[1] * w[20] + x[3] * w[21] + x[5] * w[22] + x[7] * w[23];
181 :     ; b2 = x[1] * w[24] + x[3] * w[25] + x[5] * w[26] + x[7] * w[27];
182 :     ; b3 = x[1] * w[28] + x[3] * w[29] + x[5] * w[30] + x[7] * w[31];
183 :     ;
184 :     ; y[0] = SHIFT_ROUND ( a0 + b0 );
185 :     ; y[1] = SHIFT_ROUND ( a1 + b1 );
186 :     ; y[2] = SHIFT_ROUND ( a2 + b2 );
187 :     ; y[3] = SHIFT_ROUND ( a3 + b3 );
188 :     ; y[4] = SHIFT_ROUND ( a3 - b3 );
189 :     ; y[5] = SHIFT_ROUND ( a2 - b2 );
190 :     ; y[6] = SHIFT_ROUND ( a1 - b1 );
191 :     ; y[7] = SHIFT_ROUND ( a0 - b0 );
192 :     ; }
193 :     ;
194 :     ;-----------------------------------------------------------------------------
195 :     ;
196 :     ; In this implementation the outputs of the iDCT-1D are multiplied
197 :     ; for rows 0,4 - by cos_4_16,
198 :     ; for rows 1,7 - by cos_1_16,
199 :     ; for rows 2,6 - by cos_2_16,
200 :     ; for rows 3,5 - by cos_3_16
201 :     ; and are shifted to the left for better accuracy
202 :     ;
203 :     ; For the constants used,
204 :     ; FIX(float_const) = (short) (float_const * (1<<15) + 0.5)
205 :     ;
206 : edgomez 1382 ;-----------------------------------------------------------------------------
207 : Isibaar 3
208 : edgomez 1382 ;-----------------------------------------------------------------------------
209 :     ; Tables for mmx processors
210 :     ;-----------------------------------------------------------------------------
211 : Isibaar 3
212 :     ; Table for rows 0,4 - constants are multiplied by cos_4_16
213 : edgomez 1382 tab_i_04_mmx:
214 :     dw 16384, 16384, 16384, -16384 ; movq-> w06 w04 w02 w00
215 :     dw 21407, 8867, 8867, -21407 ; w07 w05 w03 w01
216 :     dw 16384, -16384, 16384, 16384 ; w14 w12 w10 w08
217 :     dw -8867, 21407, -21407, -8867 ; w15 w13 w11 w09
218 :     dw 22725, 12873, 19266, -22725 ; w22 w20 w18 w16
219 :     dw 19266, 4520, -4520, -12873 ; w23 w21 w19 w17
220 :     dw 12873, 4520, 4520, 19266 ; w30 w28 w26 w24
221 :     dw -22725, 19266, -12873, -22725 ; w31 w29 w27 w25
222 : Isibaar 3
223 :     ; Table for rows 1,7 - constants are multiplied by cos_1_16
224 : edgomez 1382 tab_i_17_mmx:
225 :     dw 22725, 22725, 22725, -22725 ; movq-> w06 w04 w02 w00
226 :     dw 29692, 12299, 12299, -29692 ; w07 w05 w03 w01
227 :     dw 22725, -22725, 22725, 22725 ; w14 w12 w10 w08
228 :     dw -12299, 29692, -29692, -12299 ; w15 w13 w11 w09
229 :     dw 31521, 17855, 26722, -31521 ; w22 w20 w18 w16
230 :     dw 26722, 6270, -6270, -17855 ; w23 w21 w19 w17
231 :     dw 17855, 6270, 6270, 26722 ; w30 w28 w26 w24
232 :     dw -31521, 26722, -17855, -31521 ; w31 w29 w27 w25
233 : Isibaar 3
234 :     ; Table for rows 2,6 - constants are multiplied by cos_2_16
235 : edgomez 1382 tab_i_26_mmx:
236 :     dw 21407, 21407, 21407, -21407 ; movq-> w06 w04 w02 w00
237 :     dw 27969, 11585, 11585, -27969 ; w07 w05 w03 w01
238 :     dw 21407, -21407, 21407, 21407 ; w14 w12 w10 w08
239 :     dw -11585, 27969, -27969, -11585 ; w15 w13 w11 w09
240 :     dw 29692, 16819, 25172, -29692 ; w22 w20 w18 w16
241 :     dw 25172, 5906, -5906, -16819 ; w23 w21 w19 w17
242 :     dw 16819, 5906, 5906, 25172 ; w30 w28 w26 w24
243 :     dw -29692, 25172, -16819, -29692 ; w31 w29 w27 w25
244 : Isibaar 3
245 :     ; Table for rows 3,5 - constants are multiplied by cos_3_16
246 : edgomez 1382 tab_i_35_mmx:
247 :     dw 19266, 19266, 19266, -19266 ; movq-> w06 w04 w02 w00
248 :     dw 25172, 10426, 10426, -25172 ; w07 w05 w03 w01
249 :     dw 19266, -19266, 19266, 19266 ; w14 w12 w10 w08
250 :     dw -10426, 25172, -25172, -10426 ; w15 w13 w11 w09
251 :     dw 26722, 15137, 22654, -26722 ; w22 w20 w18 w16
252 :     dw 22654, 5315, -5315, -15137 ; w23 w21 w19 w17
253 :     dw 15137, 5315, 5315, 22654 ; w30 w28 w26 w24
254 :     dw -26722, 22654, -15137, -26722 ; w31 w29 w27 w25
255 : Isibaar 3
256 :     ;-----------------------------------------------------------------------------
257 : edgomez 1382 ; Tables for xmm processors
258 :     ;-----------------------------------------------------------------------------
259 : Isibaar 3
260 :     ; %3 for rows 0,4 - constants are multiplied by cos_4_16
261 : edgomez 1382 tab_i_04_xmm:
262 :     dw 16384, 21407, 16384, 8867 ; movq-> w05 w04 w01 w00
263 :     dw 16384, 8867, -16384, -21407 ; w07 w06 w03 w02
264 :     dw 16384, -8867, 16384, -21407 ; w13 w12 w09 w08
265 :     dw -16384, 21407, 16384, -8867 ; w15 w14 w11 w10
266 :     dw 22725, 19266, 19266, -4520 ; w21 w20 w17 w16
267 :     dw 12873, 4520, -22725, -12873 ; w23 w22 w19 w18
268 :     dw 12873, -22725, 4520, -12873 ; w29 w28 w25 w24
269 :     dw 4520, 19266, 19266, -22725 ; w31 w30 w27 w26
270 : Isibaar 3
271 :     ; %3 for rows 1,7 - constants are multiplied by cos_1_16
272 : edgomez 1382 tab_i_17_xmm:
273 :     dw 22725, 29692, 22725, 12299 ; movq-> w05 w04 w01 w00
274 :     dw 22725, 12299, -22725, -29692 ; w07 w06 w03 w02
275 :     dw 22725, -12299, 22725, -29692 ; w13 w12 w09 w08
276 :     dw -22725, 29692, 22725, -12299 ; w15 w14 w11 w10
277 :     dw 31521, 26722, 26722, -6270 ; w21 w20 w17 w16
278 :     dw 17855, 6270, -31521, -17855 ; w23 w22 w19 w18
279 :     dw 17855, -31521, 6270, -17855 ; w29 w28 w25 w24
280 :     dw 6270, 26722, 26722, -31521 ; w31 w30 w27 w26
281 : Isibaar 3
282 :     ; %3 for rows 2,6 - constants are multiplied by cos_2_16
283 : edgomez 1382 tab_i_26_xmm:
284 :     dw 21407, 27969, 21407, 11585 ; movq-> w05 w04 w01 w00
285 :     dw 21407, 11585, -21407, -27969 ; w07 w06 w03 w02
286 :     dw 21407, -11585, 21407, -27969 ; w13 w12 w09 w08
287 :     dw -21407, 27969, 21407, -11585 ; w15 w14 w11 w10
288 :     dw 29692, 25172, 25172, -5906 ; w21 w20 w17 w16
289 :     dw 16819, 5906, -29692, -16819 ; w23 w22 w19 w18
290 :     dw 16819, -29692, 5906, -16819 ; w29 w28 w25 w24
291 :     dw 5906, 25172, 25172, -29692 ; w31 w30 w27 w26
292 : Isibaar 3
293 :     ; %3 for rows 3,5 - constants are multiplied by cos_3_16
294 : edgomez 1382 tab_i_35_xmm:
295 :     dw 19266, 25172, 19266, 10426 ; movq-> w05 w04 w01 w00
296 :     dw 19266, 10426, -19266, -25172 ; w07 w06 w03 w02
297 :     dw 19266, -10426, 19266, -25172 ; w13 w12 w09 w08
298 :     dw -19266, 25172, 19266, -10426 ; w15 w14 w11 w10
299 :     dw 26722, 22654, 22654, -5315 ; w21 w20 w17 w16
300 :     dw 15137, 5315, -26722, -15137 ; w23 w22 w19 w18
301 :     dw 15137, -26722, 5315, -15137 ; w29 w28 w25 w24
302 :     dw 5315, 22654, 22654, -26722 ; w31 w30 w27 w26
303 : Isibaar 3
304 : edgomez 1382 ;=============================================================================
305 :     ; Helper macros for the code
306 :     ;=============================================================================
307 : Isibaar 3
308 :     ;-----------------------------------------------------------------------------
309 : edgomez 1382 ; DCT_8_INV_ROW_MMX INP, OUT, TABLE, ROUNDER
310 :     ;-----------------------------------------------------------------------------
311 : Isibaar 3
312 : edgomez 1382 %macro DCT_8_INV_ROW_MMX 4
313 :     movq mm0, [%1] ; 0 ; x3 x2 x1 x0
314 :     movq mm1, [%1+8] ; 1 ; x7 x6 x5 x4
315 :     movq mm2, mm0 ; 2 ; x3 x2 x1 x0
316 :     movq mm3, [%3] ; 3 ; w06 w04 w02 w00
317 :     punpcklwd mm0, mm1 ; x5 x1 x4 x0
318 :     movq mm5, mm0 ; 5 ; x5 x1 x4 x0
319 :     punpckldq mm0, mm0 ; x4 x0 x4 x0
320 :     movq mm4, [%3+8] ; 4 ; w07 w05 w03 w01
321 :     punpckhwd mm2, mm1 ; 1 ; x7 x3 x6 x2
322 :     pmaddwd mm3, mm0 ; x4*w06+x0*w04 x4*w02+x0*w00
323 :     movq mm6, mm2 ; 6 ; x7 x3 x6 x2
324 :     movq mm1, [%3+32] ; 1 ; w22 w20 w18 w16
325 :     punpckldq mm2, mm2 ; x6 x2 x6 x2
326 :     pmaddwd mm4, mm2 ; x6*w07+x2*w05 x6*w03+x2*w01
327 :     punpckhdq mm5, mm5 ; x5 x1 x5 x1
328 :     pmaddwd mm0, [%3+16] ; x4*w14+x0*w12 x4*w10+x0*w08
329 :     punpckhdq mm6, mm6 ; x7 x3 x7 x3
330 :     movq mm7, [%3+40] ; 7 ; w23 w21 w19 w17
331 :     pmaddwd mm1, mm5 ; x5*w22+x1*w20 x5*w18+x1*w16
332 :     paddd mm3, [%4] ; +%4
333 :     pmaddwd mm7, mm6 ; x7*w23+x3*w21 x7*w19+x3*w17
334 :     pmaddwd mm2, [%3+24] ; x6*w15+x2*w13 x6*w11+x2*w09
335 :     paddd mm3, mm4 ; 4 ; a1=sum(even1) a0=sum(even0)
336 :     pmaddwd mm5, [%3+48] ; x5*w30+x1*w28 x5*w26+x1*w24
337 :     movq mm4, mm3 ; 4 ; a1 a0
338 :     pmaddwd mm6, [%3+56] ; x7*w31+x3*w29 x7*w27+x3*w25
339 :     paddd mm1, mm7 ; 7 ; b1=sum(odd1) b0=sum(odd0)
340 :     paddd mm0, [%4] ; +%4
341 :     psubd mm3, mm1 ; a1-b1 a0-b0
342 :     psrad mm3, SHIFT_INV_ROW ; y6=a1-b1 y7=a0-b0
343 :     paddd mm1, mm4 ; 4 ; a1+b1 a0+b0
344 :     paddd mm0, mm2 ; 2 ; a3=sum(even3) a2=sum(even2)
345 :     psrad mm1, SHIFT_INV_ROW ; y1=a1+b1 y0=a0+b0
346 :     paddd mm5, mm6 ; 6 ; b3=sum(odd3) b2=sum(odd2)
347 :     movq mm4, mm0 ; 4 ; a3 a2
348 :     paddd mm0, mm5 ; a3+b3 a2+b2
349 :     psubd mm4, mm5 ; 5 ; a3-b3 a2-b2
350 :     psrad mm0, SHIFT_INV_ROW ; y3=a3+b3 y2=a2+b2
351 :     psrad mm4, SHIFT_INV_ROW ; y4=a3-b3 y5=a2-b2
352 :     packssdw mm1, mm0 ; 0 ; y3 y2 y1 y0
353 :     packssdw mm4, mm3 ; 3 ; y6 y7 y4 y5
354 :     movq mm7, mm4 ; 7 ; y6 y7 y4 y5
355 :     psrld mm4, 16 ; 0 y6 0 y4
356 :     pslld mm7, 16 ; y7 0 y5 0
357 :     movq [%2], mm1 ; 1 ; save y3 y2 y1 y0
358 :     por mm7, mm4 ; 4 ; y7 y6 y5 y4
359 :     movq [%2+8], mm7 ; 7 ; save y7 y6 y5 y4
360 :     %endmacro
361 : Isibaar 3
362 : edgomez 1382 ;-----------------------------------------------------------------------------
363 :     ; DCT_8_INV_ROW_XMM INP, OUT, TABLE, ROUNDER
364 :     ;-----------------------------------------------------------------------------
365 : Isibaar 3
366 : edgomez 1382 %macro DCT_8_INV_ROW_XMM 4
367 :     movq mm0, [%1] ; 0 ; x3 x2 x1 x0
368 :     movq mm1, [%1+8] ; 1 ; x7 x6 x5 x4
369 :     movq mm2, mm0 ; 2 ; x3 x2 x1 x0
370 :     movq mm3, [%3] ; 3 ; w05 w04 w01 w00
371 :     pshufw mm0, mm0, 10001000b ; x2 x0 x2 x0
372 :     movq mm4, [%3+8] ; 4 ; w07 w06 w03 w02
373 :     movq mm5, mm1 ; 5 ; x7 x6 x5 x4
374 :     pmaddwd mm3, mm0 ; x2*w05+x0*w04 x2*w01+x0*w00
375 :     movq mm6, [%3+32] ; 6 ; w21 w20 w17 w16
376 :     pshufw mm1, mm1, 10001000b ; x6 x4 x6 x4
377 :     pmaddwd mm4, mm1 ; x6*w07+x4*w06 x6*w03+x4*w02
378 :     movq mm7, [%3+40] ; 7 ; w23 w22 w19 w18
379 :     pshufw mm2, mm2, 11011101b ; x3 x1 x3 x1
380 :     pmaddwd mm6, mm2 ; x3*w21+x1*w20 x3*w17+x1*w16
381 :     pshufw mm5, mm5, 11011101b ; x7 x5 x7 x5
382 :     pmaddwd mm7, mm5 ; x7*w23+x5*w22 x7*w19+x5*w18
383 :     paddd mm3, [%4] ; +%4
384 :     pmaddwd mm0, [%3+16] ; x2*w13+x0*w12 x2*w09+x0*w08
385 :     paddd mm3, mm4 ; 4 ; a1=sum(even1) a0=sum(even0)
386 :     pmaddwd mm1, [%3+24] ; x6*w15+x4*w14 x6*w11+x4*w10
387 :     movq mm4, mm3 ; 4 ; a1 a0
388 :     pmaddwd mm2, [%3+48] ; x3*w29+x1*w28 x3*w25+x1*w24
389 :     paddd mm6, mm7 ; 7 ; b1=sum(odd1) b0=sum(odd0)
390 :     pmaddwd mm5, [%3+56] ; x7*w31+x5*w30 x7*w27+x5*w26
391 :     paddd mm3, mm6 ; a1+b1 a0+b0
392 :     paddd mm0, [%4] ; +%4
393 :     psrad mm3, SHIFT_INV_ROW ; y1=a1+b1 y0=a0+b0
394 :     paddd mm0, mm1 ; 1 ; a3=sum(even3) a2=sum(even2)
395 :     psubd mm4, mm6 ; 6 ; a1-b1 a0-b0
396 :     movq mm7, mm0 ; 7 ; a3 a2
397 :     paddd mm2, mm5 ; 5 ; b3=sum(odd3) b2=sum(odd2)
398 :     paddd mm0, mm2 ; a3+b3 a2+b2
399 :     psrad mm4, SHIFT_INV_ROW ; y6=a1-b1 y7=a0-b0
400 :     psubd mm7, mm2 ; 2 ; a3-b3 a2-b2
401 :     psrad mm0, SHIFT_INV_ROW ; y3=a3+b3 y2=a2+b2
402 :     psrad mm7, SHIFT_INV_ROW ; y4=a3-b3 y5=a2-b2
403 :     packssdw mm3, mm0 ; 0 ; y3 y2 y1 y0
404 :     packssdw mm7, mm4 ; 4 ; y6 y7 y4 y5
405 :     movq [%2], mm3 ; 3 ; save y3 y2 y1 y0
406 :     pshufw mm7, mm7, 10110001b ; y7 y6 y5 y4
407 :     movq [%2+8], mm7 ; 7 ; save y7 y6 y5 y4
408 : Isibaar 3 %endmacro
409 :    
410 : edgomez 1382 ;-----------------------------------------------------------------------------
411 : Isibaar 3 ;
412 :     ; The first stage DCT 8x8 - forward DCTs of columns
413 :     ;
414 :     ; The %2puts are multiplied
415 :     ; for rows 0,4 - on cos_4_16,
416 :     ; for rows 1,7 - on cos_1_16,
417 :     ; for rows 2,6 - on cos_2_16,
418 :     ; for rows 3,5 - on cos_3_16
419 :     ; and are shifted to the left for rise of accuracy
420 :     ;
421 :     ;-----------------------------------------------------------------------------
422 :     ;
423 :     ; The 8-point scaled forward DCT algorithm (26a8m)
424 :     ;
425 :     ;-----------------------------------------------------------------------------
426 :     ;
427 :     ; #define DCT_8_FRW_COL(x, y)
428 :     ;{
429 :     ; short t0, t1, t2, t3, t4, t5, t6, t7;
430 :     ; short tp03, tm03, tp12, tm12, tp65, tm65;
431 :     ; short tp465, tm465, tp765, tm765;
432 :     ;
433 :     ; t0 = LEFT_SHIFT ( x[0] + x[7] );
434 :     ; t1 = LEFT_SHIFT ( x[1] + x[6] );
435 :     ; t2 = LEFT_SHIFT ( x[2] + x[5] );
436 :     ; t3 = LEFT_SHIFT ( x[3] + x[4] );
437 :     ; t4 = LEFT_SHIFT ( x[3] - x[4] );
438 :     ; t5 = LEFT_SHIFT ( x[2] - x[5] );
439 :     ; t6 = LEFT_SHIFT ( x[1] - x[6] );
440 :     ; t7 = LEFT_SHIFT ( x[0] - x[7] );
441 :     ;
442 :     ; tp03 = t0 + t3;
443 :     ; tm03 = t0 - t3;
444 :     ; tp12 = t1 + t2;
445 :     ; tm12 = t1 - t2;
446 :     ;
447 :     ; y[0] = tp03 + tp12;
448 :     ; y[4] = tp03 - tp12;
449 :     ;
450 :     ; y[2] = tm03 + tm12 * tg_2_16;
451 :     ; y[6] = tm03 * tg_2_16 - tm12;
452 :     ;
453 :     ; tp65 =(t6 +t5 )*cos_4_16;
454 :     ; tm65 =(t6 -t5 )*cos_4_16;
455 :     ;
456 :     ; tp765 = t7 + tp65;
457 :     ; tm765 = t7 - tp65;
458 :     ; tp465 = t4 + tm65;
459 :     ; tm465 = t4 - tm65;
460 :     ;
461 :     ; y[1] = tp765 + tp465 * tg_1_16;
462 :     ; y[7] = tp765 * tg_1_16 - tp465;
463 :     ; y[5] = tm765 * tg_3_16 + tm465;
464 :     ; y[3] = tm765 - tm465 * tg_3_16;
465 :     ;}
466 :     ;
467 : edgomez 1382 ;-----------------------------------------------------------------------------
468 : Isibaar 3
469 : edgomez 1382 ;-----------------------------------------------------------------------------
470 : Isibaar 3 ; DCT_8_INV_COL_4 INP,OUT
471 : edgomez 1382 ;-----------------------------------------------------------------------------
472 : Isibaar 3
473 : edgomez 1382 %macro DCT_8_INV_COL 2
474 :     movq mm0, [tg_3_16]
475 :     movq mm3, [%1+16*3]
476 :     movq mm1, mm0 ; tg_3_16
477 :     movq mm5, [%1+16*5]
478 :     pmulhw mm0, mm3 ; x3*(tg_3_16-1)
479 :     movq mm4, [tg_1_16]
480 :     pmulhw mm1, mm5 ; x5*(tg_3_16-1)
481 :     movq mm7, [%1+16*7]
482 :     movq mm2, mm4 ; tg_1_16
483 :     movq mm6, [%1+16*1]
484 :     pmulhw mm4, mm7 ; x7*tg_1_16
485 :     paddsw mm0, mm3 ; x3*tg_3_16
486 :     pmulhw mm2, mm6 ; x1*tg_1_16
487 :     paddsw mm1, mm3 ; x3+x5*(tg_3_16-1)
488 :     psubsw mm0, mm5 ; x3*tg_3_16-x5 = tm35
489 :     movq mm3, [ocos_4_16]
490 :     paddsw mm1, mm5 ; x3+x5*tg_3_16 = tp35
491 :     paddsw mm4, mm6 ; x1+tg_1_16*x7 = tp17
492 :     psubsw mm2, mm7 ; x1*tg_1_16-x7 = tm17
493 :     movq mm5, mm4 ; tp17
494 :     movq mm6, mm2 ; tm17
495 :     paddsw mm5, mm1 ; tp17+tp35 = b0
496 :     psubsw mm6, mm0 ; tm17-tm35 = b3
497 :     psubsw mm4, mm1 ; tp17-tp35 = t1
498 :     paddsw mm2, mm0 ; tm17+tm35 = t2
499 :     movq mm7, [tg_2_16]
500 :     movq mm1, mm4 ; t1
501 :     ; movq [SCRATCH+0], mm5 ; save b0
502 :     movq [%2+3*16], mm5 ; save b0
503 :     paddsw mm1, mm2 ; t1+t2
504 :     ; movq [SCRATCH+8], mm6 ; save b3
505 :     movq [%2+5*16], mm6 ; save b3
506 :     psubsw mm4, mm2 ; t1-t2
507 :     movq mm5, [%1+2*16]
508 :     movq mm0, mm7 ; tg_2_16
509 :     movq mm6, [%1+6*16]
510 :     pmulhw mm0, mm5 ; x2*tg_2_16
511 :     pmulhw mm7, mm6 ; x6*tg_2_16
512 : Isibaar 3 ; slot
513 : edgomez 1382 pmulhw mm1, mm3 ; ocos_4_16*(t1+t2) = b1/2
514 : Isibaar 3 ; slot
515 : edgomez 1382 movq mm2, [%1+0*16]
516 :     pmulhw mm4, mm3 ; ocos_4_16*(t1-t2) = b2/2
517 :     psubsw mm0, mm6 ; t2*tg_2_16-x6 = tm26
518 :     movq mm3, mm2 ; x0
519 :     movq mm6, [%1+4*16]
520 :     paddsw mm7, mm5 ; x2+x6*tg_2_16 = tp26
521 :     paddsw mm2, mm6 ; x0+x4 = tp04
522 :     psubsw mm3, mm6 ; x0-x4 = tm04
523 :     movq mm5, mm2 ; tp04
524 :     movq mm6, mm3 ; tm04
525 :     psubsw mm2, mm7 ; tp04-tp26 = a3
526 :     paddsw mm3, mm0 ; tm04+tm26 = a1
527 :     paddsw mm1, mm1 ; b1
528 :     paddsw mm4, mm4 ; b2
529 :     paddsw mm5, mm7 ; tp04+tp26 = a0
530 :     psubsw mm6, mm0 ; tm04-tm26 = a2
531 :     movq mm7, mm3 ; a1
532 :     movq mm0, mm6 ; a2
533 :     paddsw mm3, mm1 ; a1+b1
534 :     paddsw mm6, mm4 ; a2+b2
535 :     psraw mm3, SHIFT_INV_COL ; dst1
536 :     psubsw mm7, mm1 ; a1-b1
537 :     psraw mm6, SHIFT_INV_COL ; dst2
538 :     psubsw mm0, mm4 ; a2-b2
539 :     ; movq mm1, [SCRATCH+0] ; load b0
540 :     movq mm1, [%2+3*16] ; load b0
541 :     psraw mm7, SHIFT_INV_COL ; dst6
542 :     movq mm4, mm5 ; a0
543 :     psraw mm0, SHIFT_INV_COL ; dst5
544 :     movq [%2+1*16], mm3
545 :     paddsw mm5, mm1 ; a0+b0
546 :     movq [%2+2*16], mm6
547 :     psubsw mm4, mm1 ; a0-b0
548 :     ; movq mm3, [SCRATCH+8] ; load b3
549 :     movq mm3, [%2+5*16] ; load b3
550 :     psraw mm5, SHIFT_INV_COL ; dst0
551 :     movq mm6, mm2 ; a3
552 :     psraw mm4, SHIFT_INV_COL ; dst7
553 :     movq [%2+5*16], mm0
554 :     paddsw mm2, mm3 ; a3+b3
555 :     movq [%2+6*16], mm7
556 :     psubsw mm6, mm3 ; a3-b3
557 :     movq [%2+0*16], mm5
558 :     psraw mm2, SHIFT_INV_COL ; dst3
559 :     movq [%2+7*16], mm4
560 :     psraw mm6, SHIFT_INV_COL ; dst4
561 :     movq [%2+3*16], mm2
562 :     movq [%2+4*16], mm6
563 : Isibaar 3 %endmacro
564 :    
565 :     ;=============================================================================
566 : edgomez 1382 ; Code
567 : Isibaar 3 ;=============================================================================
568 :    
569 : edgomez 1382 SECTION .text
570 : Isibaar 3
571 : edgomez 1382 cglobal idct_mmx
572 : Isibaar 3 cglobal idct_xmm
573 :    
574 : edgomez 1382 ;-----------------------------------------------------------------------------
575 :     ; void idct_mmx(uint16_t block[64]);
576 :     ;-----------------------------------------------------------------------------
577 : Isibaar 3
578 : edgomez 1382 ALIGN 16
579 :     idct_mmx:
580 :     mov eax, dword [esp + 4]
581 : Isibaar 3
582 : edgomez 1382 ;; Process each row
583 :     DCT_8_INV_ROW_MMX eax+0*16, eax+0*16, tab_i_04_mmx, rounder_0
584 :     DCT_8_INV_ROW_MMX eax+1*16, eax+1*16, tab_i_17_mmx, rounder_1
585 :     DCT_8_INV_ROW_MMX eax+2*16, eax+2*16, tab_i_26_mmx, rounder_2
586 :     DCT_8_INV_ROW_MMX eax+3*16, eax+3*16, tab_i_35_mmx, rounder_3
587 :     DCT_8_INV_ROW_MMX eax+4*16, eax+4*16, tab_i_04_mmx, rounder_4
588 :     DCT_8_INV_ROW_MMX eax+5*16, eax+5*16, tab_i_35_mmx, rounder_5
589 :     DCT_8_INV_ROW_MMX eax+6*16, eax+6*16, tab_i_26_mmx, rounder_6
590 :     DCT_8_INV_ROW_MMX eax+7*16, eax+7*16, tab_i_17_mmx, rounder_7
591 : Isibaar 154
592 : edgomez 1382 ;; Process the columns (4 at a time)
593 :     DCT_8_INV_COL eax+0, eax+0
594 :     DCT_8_INV_COL eax+8, eax+8
595 : Isibaar 154
596 : edgomez 1382 ret
597 : Isibaar 154
598 : edgomez 1382 ;-----------------------------------------------------------------------------
599 :     ; void idct_xmm(uint16_t block[64]);
600 :     ;-----------------------------------------------------------------------------
601 : Isibaar 154
602 : edgomez 1382 ALIGN 16
603 :     idct_xmm:
604 :     mov eax, dword [esp + 4]
605 : Isibaar 154
606 : edgomez 1382 ;; Process each row
607 :     DCT_8_INV_ROW_XMM eax+0*16, eax+0*16, tab_i_04_xmm, rounder_0
608 :     DCT_8_INV_ROW_XMM eax+1*16, eax+1*16, tab_i_17_xmm, rounder_1
609 :     DCT_8_INV_ROW_XMM eax+2*16, eax+2*16, tab_i_26_xmm, rounder_2
610 :     DCT_8_INV_ROW_XMM eax+3*16, eax+3*16, tab_i_35_xmm, rounder_3
611 :     DCT_8_INV_ROW_XMM eax+4*16, eax+4*16, tab_i_04_xmm, rounder_4
612 :     DCT_8_INV_ROW_XMM eax+5*16, eax+5*16, tab_i_35_xmm, rounder_5
613 :     DCT_8_INV_ROW_XMM eax+6*16, eax+6*16, tab_i_26_xmm, rounder_6
614 :     DCT_8_INV_ROW_XMM eax+7*16, eax+7*16, tab_i_17_xmm, rounder_7
615 : Isibaar 154
616 : edgomez 1382 ;; Process the columns (4 at a time)
617 :     DCT_8_INV_COL eax+0, eax+0
618 :     DCT_8_INV_COL eax+8, eax+8
619 : Isibaar 154
620 : edgomez 1382 ret
No admin address has been configured
 ViewVC Help
Powered by ViewVC 1.0.4